(VBScript) Firebase PATCH - Updating Data

Uses the PATCH method to update record with new information. The data used in this example is at Chilkat Firebase Pigs Database, and is shown here:

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Uses the PATCH method to update a Firebase record.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a JWT authentication token, if required, has been previously obtained.
' See Get Firebase Access Token from JSON Service Account Private Key for sample code.

' Load the previously obtained Firebase access token into a string.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
accessToken = fac.ReadEntireTextFile("qa_data/tokens/firebaseToken.txt","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Make the initial connection (without sending a request yet).
' Once connected, any number of requests may be sent.  It is not necessary to explicitly
' call Connect before each request.  
success = rest.Connect("chilkat.firebaseio.com",443,1,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set authGoogle = CreateObject("Chilkat.AuthGoogle")
authGoogle.AccessToken = accessToken
success = rest.SetAuthGoogle(authGoogle)

' Chilkat's sample data (pig-rescue data) is publicly readable at: https://chilkat.firebaseio.com/.json
' This data is publicly readable, but not writable.  You'll need to 
' run against your own database..

' We're going to update "Molly II" to "Molly III"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set pigNameUpdate = CreateObject("Chilkat.JsonObject")
success = pigNameUpdate.AppendString("name","Molly III")

' The string content of the last arg passed is  {"name":"Molly III"} 
jsonResponse = rest.FullRequestString("PATCH","/pig-rescue/animal/-KI3bD-FU_Dake7sYOiP.json",pigNameUpdate.Emit())
If (rest.LastMethodSuccess <> 1) Then
    ' Something happened in the communications (either no request was sent, or no response was received.
    ' (The Chilkat REST API also has lower-level methods where an app can send the request in one call,
    ' and then receive the response in another call.)
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Check the response status code.   A 200 response status indicates success.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine(rest.ResponseStatusText)
    outFile.WriteLine(jsonResponse)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' When successful, the response contains the data written.
outFile.WriteLine(jsonResponse)
outFile.WriteLine("Success.")

outFile.Close