(VBScript) Get Firebase Access Token from JSON Service Account Private Key

Demonstrates how to get a Firebase access token using a JSON service account private key. Your Firebase service account can be used to authenticate multiple Firebase features, such as Database, Storage and Auth, programmatically.

A Firebase JSON service account private key can be created in the Firebase settings/admin portion of the console.firebase.google.com site as shown here:

Scroll down to see the example code...

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the Firebase JSON private key into a string.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.FileAccess")
set fac = CreateObject("Chilkat.FileAccess")
jsonKey = fac.ReadEntireTextFile("qa_data/firebase/firebase-chilkat-firebase-adminsdk-n28n4-1b664ee163.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' A Firebase JSON private key should look something like this:

' { 
'   "type": "service_account",
'   "project_id": "firebase-chilkat",
'   "private_key_id": "1c664ee164907413c91ddefcf5b765ecba8779e2",
'   "private_key": "-----BEGIN PRIVATE KEY-----\nMIIEvQIBA ... Ya2UZii/lXn73/ZOK8=\n-----END PRIVATE KEY-----\n",
'   "client_email": "firebase-adminsdk-n28n4@firebase-chilkat.iam.gserviceaccount.com",
'   "client_id": "134846322329335418431",
'   "auth_uri": "https://accounts.google.com/o/oauth2/auth",
'   "token_uri": "https://accounts.google.com/o/oauth2/token",
'   "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
'   "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/firebase-adminsdk-n28n4%40firebase-chilkat.iam.gserviceaccount.com"
' } 
' 

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthGoogle")
set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.JsonKey = jsonKey

' Choose a scope.
' The scope could be "https://www.googleapis.com/auth/firebase.database"
' or a space-delimited list of scopes:
' "https://www.googleapis.com/auth/firebase.database https://www.googleapis.com/auth/userinfo.email"

gAuth.Scope = "https://www.googleapis.com/auth/firebase.database https://www.googleapis.com/auth/userinfo.email"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Socket")
set tlsSock = CreateObject("Chilkat.Socket")
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    outFile.WriteLine(tlsSock.LastErrorText)
    WScript.Quit
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    outFile.WriteLine(gAuth.LastErrorText)
    WScript.Quit
End If

' Examine the access token:
outFile.WriteLine("Firebase Access Token: " & gAuth.AccessToken)

' Save the token to a file (or wherever desired).  This token is valid for 1 hour.
success = fac.WriteEntireTextFile("qa_data/tokens/firebaseToken.txt",gAuth.AccessToken,"utf-8",0)

outFile.Close