Visual Basic 6.0

Send HTML Email with Embedded Image Loaded from Memory

Demonstrates how to compose an HTML email with an embedded image where the image data is loaded directly from memory.

Chilkat Visual Basic 6.0 Downloads

Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load image data into memory.
' This example loads image data from a file.
' However, your application could get the image data from any other source, such as
' from a database.
Dim fac As New CkFileAccess
Dim imageBytes() As Byte
imageBytes = fac.ReadEntireFile("qa_data/jpg/starfish.jpg")

' The mailman object is used for sending and receiving email.
Dim mailman As New ChilkatMailMan

' Use your SMTP server hostname.  This example uses office365, but it could be any SMTP server..
mailman.SmtpHost = "outlook.office365.com"
mailman.SmtpPort = 587
mailman.StartTLS = 1

' Set the SMTP login/password
mailman.SmtpUsername = "OFFICE365-SMTP-LOGIN"
mailman.SmtpPassword = "OFFICE365-SMTP-PASSWORD"

' Create a new email object
Dim email As New ChilkatEmail
email.Subject = "HTML Email with Image Loaded from In-Memory Bytes"
email.From = "Chilkat Support <my-office365-user@mydomain.com>"
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

Dim contentIdStarfish As String
contentIdStarfish = email.AddRelatedData("starfish.jpg",imageBytes)
If (email.LastMethodSuccess <> 1) Then
    Debug.Print email.LastErrorText
    Exit Sub
End If

' The src attribute for the image tag is set to the contentIdStarfish:
Dim sbHtml As New ChilkatStringBuilder
success = sbHtml.Append("<html><body><p>This is an HTML email with an embedded image.</p>")
success = sbHtml.Append("<p><img src=""cid:CONTENT_ID_STARFISH"" /></p></body></html>")
Dim numReplacements As Long
numReplacements = sbHtml.Replace("CONTENT_ID_STARFISH",contentIdStarfish)

email.SetHtmlBody sbHtml.GetAsString()

success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
Else
    Debug.Print "Mail Sent!"
End If