(Visual Basic 6.0) Office365 Refresh OAuth2 Access Token for SMTP, IMAP, POP

See more Office365 Examples

Demonstrates how to refresh an Office365 OAuth2 access token for use in the SMTP, IMAP, and POP3 protocols.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Office365 SMTP/IMAP/POP3 OAuth2 Access Token

' Note: Refreshing an access token does not require user-interaction.  
' Only the act of getting the initial access token requires interactive authorization from the Office365 account owner 
' (i.e. a browser is displayed and the account owner authorizes access by the app).

' Once you have the initial access token, it can be refreshed over and over again with no limits.
' A typical strategy is to write your application to automatically refresh the access token 
' when authentication fails, and then retry the operation with the new access token.
' For example, see Auto-Refresh O365 Access Token when Sending Email

Dim jsonToken As New ChilkatJsonObject
Dim success As Long
success = jsonToken.LoadFile("qa_data/tokens/office365.json")
If (success <> 1) Then
    Debug.Print "Failed to load office365.json"
    Exit Sub
End If

' The access token JSON looks like this:

' {
'   "token_type": "Bearer",
'   "scope": "IMAP.AccessAsUser.All openid POP.AccessAsUser.All profile SMTP.Send email",
'   "expires_in": 3599,
'   "ext_expires_in": 3599,
'   "access_token": "...",
'   "refresh_token": "...",
'   "id_token": "...",
'   "expires_on": "1592748507"
' }

Dim oauth2 As New ChilkatOAuth2

' Update to use your token endpoint.
' In the Azure Portal, in "App registrations", go to "Endpoints" (located to the right of the "+ New registration" link.)
'    Find your endpoint for the "OAuth 2.0 token endpoint (v2)"
'    See Office365 OAuth2 Endpoints

oauth2.TokenEndpoint = "https://login.microsoftonline.com/xxxxxxxxxx-71bf-4ebe-a866-738364321bf2/oauth2/v2.0/token"

' Replace these with actual values.
oauth2.ClientId = "CLIENT_ID"
oauth2.ClientSecret = "CLIENT_SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    Debug.Print oauth2.LastErrorText
    Exit Sub
End If

Debug.Print "New access token: " & oauth2.AccessToken
Debug.Print "New refresh token: " & oauth2.RefreshToken

' Update the JSON with the new tokens.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)
success = jsonToken.UpdateString("refresh_token",oauth2.RefreshToken)

' Save the new JSON access token response to a file.
Dim sbJson As New ChilkatStringBuilder
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/office365.json","utf-8",0)

Debug.Print "OAuth2 authorization granted!"
Debug.Print "New Access Token = " & oauth2.AccessToken