Visual Basic 6.0

Send XML REST Request, Get Response with No Body (Google Cloud Storage)

See more REST Examples

Demonstrates sending a RESTful XML request, and receiving a response where the expected response is a header with no body (Content-Length = 0). This example will create a bucket in Google Cloud Storage using the Google Cloud Storage XML API.

See Create a Bucket using the XML API for additional request options.

Visual Basic 6.0

Dim success As Long
success = 0

' This example will create a bucket in Google Cloud Storage using the XML API.

' It requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim gAuth As New ChilkatAuthGoogle
' Obtain an access token as shown in one of the following examples:
' See Get Access Token using a Service Account JSON Key
' See Get Access Token using a P12 File

Dim rest As New ChilkatRest

' Connect using TLS.
Dim bAutoReconnect As Long
bAutoReconnect = 1
success = rest.Connect("www.googleapis.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthGoogle(gAuth)

' Build the XML request body for creating a bucket.
' See https://cloud.google.com/storage/docs/xml-api/put-bucket-create
Dim xmlReqBody As New ChilkatXml
xmlReqBody.Tag = "CreateBucketConfiguration"
xmlReqBody.NewChild2 "LocationConstraint","us"
xmlReqBody.NewChild2 "StorageClass","STANDARD"

' Show the HTTP request body we'll be sending.
Debug.Print xmlReqBody.GetXml()

' There are no query parameters...

' The HOST header must be specified, because it needs to be different than
' the domain previously passed to the Connect method.
' The name of the bucket is the 1st part of the HOST header.
success = rest.AddHeader("Host","chilkat-example-bucket.storage.googleapis.com")

' The project ID is specified in an HTTP request header
success = rest.AddHeader("x-goog-project-id","chilkattest-1050")

' In this case, the response body is expected to be empty.  We can still
' call FullRequestString.  We expect an empty string to be returned.
Dim responseStr As String
responseStr = rest.FullRequestString("PUT","/",xmlReqBody.GetXml())
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' Check the response status code to make sure it is 200.
Dim responseStatus As Long
responseStatus = rest.ResponseStatusCode
Debug.Print "Response Status Code = " & responseStatus