(Visual Basic 6.0) Get Google API Access Token using JSON Private Key

Demonstrates how to get a Google API access token using a JSON service account private key.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First load the JSON key into a string.
Dim fac As New CkFileAccess
Dim jsonKey As String
jsonKey = fac.ReadEntireTextFile("qa_data/googleApi/ChilkatTest-ab2ecd52ef98.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    Debug.Print fac.LastErrorText
    Exit Sub
End If

' A JSON private key should look like this:

' 	{
' 	  "type": "service_account",
' 	  "project_id": "chilkattest-1350",
' 	  "private_key_id": "fa2e36ee26986eab628b59868af8bec1d1c64c38",
' 	  "private_key": "-----BEGIN PRIVATE KEY-----\nMIIEvgIjFa...28N64N2n1E4FYzBZjSdy\n-----END PRIVATE KEY-----\n",
' 	  "client_email": "598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a@developer.gserviceaccount.com",
' 	  "client_id": "598922945226-00rb0ppfg0snd9jo7bhvd4v17jtj2d3a.apps.googleusercontent.com",
' 	  "auth_uri": "https://accounts.google.com/o/oauth2/auth",
' 	  "token_uri": "https://accounts.google.com/o/oauth2/token",
' 	  "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
' 	  "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a%40developer.gserviceaccount.com"
' 	}

Dim gAuth As New ChilkatAuthGoogle
gAuth.JsonKey = jsonKey

' Choose a scope.
gAuth.Scope = "https://www.googleapis.com/auth/cloud-platform"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
Dim tlsSock As New ChilkatSocket
Dim success As Long
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    Debug.Print tlsSock.LastErrorText
    Exit Sub
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    Debug.Print gAuth.LastErrorText
    Exit Sub
End If

' Examine the access token:
Debug.Print "Access Token: " & gAuth.AccessToken