Visual Basic 6.0

Office365 Send Email using SMTP with OAuth2 Authentication

See more Office365 Examples

Demonstrates how to send email from smtp.office365.com using OAuth2 authentication. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' An Office365 OAuth2 access token must first be obtained prior
' to running this code.

' Getting the OAuth2 access token for the 1st time requires the O365 account owner's 
' interactive authorization via a web browser.  Afterwards, the access token
' can be repeatedly refreshed automatically (with no user interaction).

' See the following examples for getting and refreshing an OAuth2 access token

' Get Office365 SMTP/IMAP/POP3 OAuth2 Access Token
' Refresh Office365 SMTP/IMAP/POP3 OAuth2 Access Token

' First get our previously obtained OAuth2 access token.
Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/office365.json")

Dim mailman As New ChilkatMailMan

mailman.SmtpHost = "smtp.office365.com"
mailman.SmtpPort = 587
mailman.StartTLS = 1

' Use your Office365 email address for the SmtpUsername.
mailman.SmtpUsername = "OFFICE365_EMAIL_ADDRESS"
mailman.OAuth2AccessToken = jsonToken.StringOf("access_token")

' Create a new email object
Dim email As New ChilkatEmail

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "MY_NAME <OFFICE365_EMAIL_ADDRESS>"
success = email.AddTo("John Doe","somebody@example.com")

' Call SendEmail to connect to the SMTP server and send.
' The connection (i.e. session) to the SMTP server remains
' open so that subsequent SendEmail calls may use the
' same connection.  
success = mailman.SendEmail(email)
If (success <> 1) Then
    Debug.Print mailman.LastErrorText
    Exit Sub
End If

' If SendEmail failed because of "Failed to get initial SMTP Response", then it may be 
' a firewall or anti-virus blocking communications.
' See https://cknotes.com/smtp-office365-com-failed-to-get-initial-smtp-response/

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Debug.Print "Connection to SMTP server not closed cleanly."
End If

Debug.Print "Mail Sent!"