Visual Basic 6.0

IMAP Auto-Refresh Office365 Access Token

See more Office365 Examples

Demonstrates how to automatically recover from an expired access token when OAuth2 authentication fails in the IMAP protocol. If the server responds with "NO AUTHENTICATE failed.", then we refresh the access token and retry. Visual Basic 6.0

Dim success As Long
success = 0

' An Office365 OAuth2 access token must first be obtained prior
' to running this code.

' Getting the OAuth2 access token for the 1st time requires the O365 account owner's 
' interactive authorizaition via a web browser.  Afterwards, the access token
' can be repeatedly refreshed automatically.

' See the following examples for getting and refreshing an OAuth2 access token

' Get Office365 SMTP/IMAP/POP3 OAuth2 Access Token
' Refresh Office365 SMTP/IMAP/POP3 OAuth2 Access Token

' First get our previously obtained OAuth2 access token.
Dim jsonToken As New ChilkatJsonObject
success = jsonToken.LoadFile("qa_data/tokens/office365.json")
If (success = 0) Then
    Debug.Print "Failed to open the office365 OAuth JSON file."
    Exit Sub
End If

Dim imap As New ChilkatImap

imap.Ssl = 1
imap.Port = 993

' Connect to the Office365 IMAP server.
success = imap.Connect("outlook.office365.com")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Use OAuth2 authentication.
imap.AuthMethod = "XOAUTH2"

' Login using our username (i.e. email address) and the access token for the password.
success = imap.Login("OFFICE365_EMAIL_ADDRESS",jsonToken.StringOf("access_token"))
If (success <> 1) Then
    Dim loginLastErrorText As String
    loginLastErrorText = imap.LastErrorText

    ' If we're still connected to the mail server, then it means the server sent a non-success response,
    ' Such as:  NO AUTHENTICATE failed.
    If (imap.IsConnected() = 1) Then

        ' Refresh the OAuth2 access token, and if successful, save the new (refreshed) access token and try authenticating again.
        Dim oauth2 As New ChilkatOAuth2

        ' Use your actual Directory (tenant) ID instead of "112d7ed6-71bf-4eba-a866-738364321bfc"
        oauth2.TokenEndpoint = "https://login.microsoftonline.com/112d7ed6-71bf-4eba-a866-738364321bfc/oauth2/v2.0/token"

        ' Replace these with your Azure App Registration's actual values.
        oauth2.ClientId = "CLIENT_ID"
        oauth2.ClientSecret = "CLIENT_SECRET"

        ' Get the "refresh_token"
        oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

        ' Send the HTTP POST to refresh the access token..
        success = oauth2.RefreshAccessToken()
        If (success <> 1) Then
            Debug.Print oauth2.LastErrorText
            Exit Sub
        End If

        Debug.Print "New access token: " & oauth2.AccessToken
        Debug.Print "New refresh token: " & oauth2.RefreshToken

        ' Update the JSON with the new tokens.
        success = jsonToken.UpdateString("access_token",oauth2.AccessToken)
        success = jsonToken.UpdateString("refresh_token",oauth2.RefreshToken)

        ' Save the new JSON access token response to a file.
        Dim sbJson As New ChilkatStringBuilder
        jsonToken.EmitCompact = 0
        success = jsonToken.EmitSb(sbJson)
        success = sbJson.WriteFile("qa_data/tokens/office365.json","utf-8",0)

        Debug.Print "New Access Token = " & oauth2.AccessToken

        ' Retry the login.
        success = imap.Login("OFFICE365_EMAIL_ADDRESS",jsonToken.StringOf("access_token"))
        If (success = 0) Then
            Debug.Print imap.LastErrorText
            Exit Sub
        End If

    Else
        ' Show the last error text for the call to Login
        Debug.Print loginLastErrorText
        Exit Sub
    End If

Else
    Debug.Print "O365 OAuth authentication is successful."
End If

' Do something...
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    Debug.Print imap.LastErrorText
    Exit Sub
End If

' Your application can continue to do other things in the IMAP session....

' When finished, logout and close the connection.
success = imap.Logout()
success = imap.Disconnect()

Debug.Print "Finished."