(Visual Basic 6.0) Generate an E-way Bill

Demonstrates how to send an HTTP POST request to generate an e-way bill.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example uses the previously obtained access token that was retrieved
'  in this example:  Get EWAY Auth Token using Gstin, username, password, and app_key

Dim jsonAuth As New ChilkatJsonObject
Dim success As Long
success = jsonAuth.LoadFile("qa_data/tokens/ewayAuth.json")
If (success <> 1) Then
    Debug.Print jsonAuth.LastErrorText
    Exit Sub
End If

'  The jsonAuth contains something like this:
'  {
'    "authToken": "IBTeFtxNfVurg71LTzZ2r0xK7",
'    "decryptedSek": "5g1TyTie7yoslU3DrbYATa7mWyPazlODE7cEh5Vy4Ho="
'  }

'  Generate the JSON data for the e-way bill.
'  The following code can be generated by pasting representative JSON into this online tool:
'  Generate JSON Code
Dim jsonData As New ChilkatJsonObject
success = jsonData.UpdateString("supplyType","O")
success = jsonData.UpdateString("subSupplyType","1")
success = jsonData.UpdateString("docType","INV")
success = jsonData.UpdateString("docNo","AW1234-2")
success = jsonData.UpdateString("docDate","05/04/2018")
success = jsonData.UpdateString("fromGstin","09ABDC24212B1FK")
success = jsonData.UpdateString("fromTrdName","willy")
success = jsonData.UpdateString("fromAddr1","3RD CROSS NO 200  19  A")
success = jsonData.UpdateString("fromAddr2","GROUND FLOOR OZZY ROAD")
success = jsonData.UpdateString("fromPlace","BUSY TOWN")
success = jsonData.UpdateNumber("fromPincode","640033")
success = jsonData.UpdateNumber("actFromStateCode","05")
success = jsonData.UpdateNumber("fromStateCode","05")
success = jsonData.UpdateString("toGstin","01AAAASCC10BBBB")
success = jsonData.UpdateString("toTrdName","mthustra")
success = jsonData.UpdateString("toAddr1","Shrek Ogre")
success = jsonData.UpdateString("toAddr2","Basadronsil")
success = jsonData.UpdateString("toPlace","Grifl Blagar")
success = jsonData.UpdateNumber("toPincode","699988")
success = jsonData.UpdateNumber("actToStateCode","29")
success = jsonData.UpdateNumber("toStateCode","02")
success = jsonData.UpdateNumber("totalValue","5609889")
success = jsonData.UpdateNumber("cgstValue","0")
success = jsonData.UpdateNumber("sgstValue","0")
success = jsonData.UpdateNumber("igstValue","168296.67")
success = jsonData.UpdateNumber("cessValue","224395.56")
success = jsonData.UpdateString("transporterId","09ABDC24212B1FK")
success = jsonData.UpdateString("transporterName","")
success = jsonData.UpdateString("transDocNo","12332")
success = jsonData.UpdateNumber("transMode","1")
success = jsonData.UpdateString("transDistance","656")
success = jsonData.UpdateString("transDocDate","10/04/2018")
success = jsonData.UpdateString("vehicleNo","PBN4567")
success = jsonData.UpdateString("vehicleType","R")
jsonData.I = 0
success = jsonData.UpdateString("itemList[i].productName","Wheat")
success = jsonData.UpdateString("itemList[i].productDesc","Wheat")
success = jsonData.UpdateNumber("itemList[i].hsnCode","1001")
success = jsonData.UpdateNumber("itemList[i].quantity","4")
success = jsonData.UpdateString("itemList[i].qtyUnit","BOX")
success = jsonData.UpdateNumber("itemList[i].cgstRate","0")
success = jsonData.UpdateNumber("itemList[i].sgstRate","0")
success = jsonData.UpdateNumber("itemList[i].igstRate","3")
success = jsonData.UpdateNumber("itemList[i].cessRate","4")
success = jsonData.UpdateNumber("itemList[i].cessAdvol","0")
success = jsonData.UpdateNumber("itemList[i].taxableAmount","5609889")

'  The body of the HTTP POST will contain JSON that looks like this:
'  	{
'  	"action":"GENEWAYBILL",
'  	"data": " iJiJGXq ... oUZp/25Y "
'  	}

'  The "data" is the encrypted jsonData using our previously agreed-upon symmetric encryption key.
'  Let's begin build the JSON request body..
Dim jsonRequestBody As New ChilkatJsonObject
success = jsonRequestBody.UpdateString("action","GENEWAYBILL")

'  Setup the encryptor using the decryptedSek from the jsonAuth
Dim crypt As New ChilkatCrypt2
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "ecb"
crypt.KeyLength = 256
crypt.SetEncodedKey jsonAuth.StringOf("decryptedSek"),"base64"
crypt.EncodingMode = "base64"

'  Encrypt the jsonData and add it to our JSON request body
success = jsonRequestBody.UpdateString("data",crypt.EncryptStringENC(jsonData.Emit()))

Dim http As New ChilkatHttp

'  Add the authtoken to the request header.
'  Be careful to be precise with uppercase/lowercase ("authtoken" vs "authToken")
http.SetRequestHeader "authtoken",jsonAuth.StringOf("authToken")
http.SetRequestHeader "Gstin","09ABDC24212B1FK"
http.Accept = "application/json"

'  POST the request to generate an e-way bill:
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson2("http://ewb.wepgst.com/api/EWayBill","application/json",jsonRequestBody.Emit())
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim respStatusCode As Long
respStatusCode = resp.StatusCode
Debug.Print "response status code =" & respStatusCode
Debug.Print "response body:"
Debug.Print resp.BodyStr

If (respStatusCode <> 200) Then

    Debug.Print "Failed in some unknown way."
    Exit Sub
End If

'  When the response status code = 200, we'll have either
'  success response like this:
'   {"status":"1","data":"..."}
' 
'  or a failed response like this:
' 
'  {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}

'  Load the response body into a JSON object.
Dim json As New ChilkatJsonObject
success = json.Load(resp.BodyStr)

Dim status As Long
status = json.IntOf("status")
Debug.Print "status = " & status

If (status <> 1) Then
    '  Failed.  Base64 decode the error
    ' {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}
    '  For an invalid password, the error is: {"errorCodes":"108"}
    Dim sbError As New ChilkatStringBuilder
    success = json.StringOfSb("error",sbError)
    success = sbError.Decode("base64","utf-8")
    Debug.Print "error: " & sbError.GetAsString()
    Exit Sub
End If

json.EmitCompact = 0
Debug.Print "JSON response:"
Debug.Print json.Emit()

Dim bdData As New ChilkatBinData
success = bdData.AppendEncoded(json.StringOf("data"),"base64")
success = crypt.DecryptBd(bdData)

'  Decrypts to
'  {"ewayBillNo":331001121234,"ewayBillDate":"24/05/2018 04:38:00 PM","validUpto":"31/05/2018 11:59:00 PM"}

Dim jsonBill As New ChilkatJsonObject
success = jsonBill.Load(bdData.GetString("utf-8"))

Dim ewayBillNo As Long
ewayBillNo = jsonBill.IntOf("ewayBillNo")
Debug.Print "ewayBillNo = " & ewayBillNo

Dim ewayBillDate As String
ewayBillDate = jsonBill.StringOf("ewayBillDate")
Debug.Print "ewayBillDate = " & ewayBillDate

Dim validUpto As String
validUpto = jsonBill.StringOf("validUpto")
Debug.Print "validUpto = " & validUpto

'  Sample output:

'  ewayBillNo = 331001121234
'  ewayBillDate = 24/05/2018 04:55:00 PM
'  validUpto = 31/05/2018 11:59:00 PM