(Visual Basic 6.0) Get E-way Bill System Access Token

Sends a request to get an E-way bill system access token.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  First load the public key provided by the E-way bill System
Dim pubkey As New PublicKey
Dim success As Long
success = pubkey.LoadFromFile("qa_data/pem/eway_publickey.pem")
If (success <> 1) Then
    Debug.Print pubkey.LastErrorText
    Exit Sub
End If

'  Encrypt the password using the RSA public key provided by eway..
Dim password As String
password = "my_wepgst_password"
Dim rsa As New ChilkatRsa
rsa.Charset = "utf-8"
rsa.EncodingMode = "base64"

success = rsa.ImportPublicKeyObj(pubkey)
If (success <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

'  Returns the encrypted password as base64 (because the EncodingMode = "base64")
Dim encPassword As String
encPassword = rsa.EncryptStringENC(password,0)
If (rsa.LastMethodSuccess <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

'  Generate a random app_key.  This should be 32 bytes (us-ascii chars)
'  We need 32 bytes because we'll be doing 256-bit AES ECB encryption, and 32 bytes = 256 bits.
Dim prng As New ChilkatPrng
'  Generate a random string containing some numbers, uppercase, and lowercase.
Dim app_key As String
app_key = prng.RandomString(32,1,1,1)

Debug.Print "app_key = " & app_key

'  RSA encrypt the app_key.
Dim encAppKey As String
encAppKey = rsa.EncryptStringENC(app_key,0)
If (rsa.LastMethodSuccess <> 1) Then
    Debug.Print rsa.LastErrorText
    Exit Sub
End If

'  Prepare the JSON body for the HTTP POST that gets the access token.
Dim jsonBody As New ChilkatJsonObject
success = jsonBody.UpdateString("action","ACCESSTOKEN")
'  Use your username instead of "09ABDC24212B1FK".
success = jsonBody.UpdateString("username","09ABDC24212B1FK")
success = jsonBody.UpdateString("password",encPassword)
success = jsonBody.UpdateString("app_key",encAppKey)

Dim http As New ChilkatHttp

'  Add required headers.
'  Use your ewb-user-id instead of "03AEXPR16A9M010"
http.SetRequestHeader "ewb-user-id","03AEXPR16A9M010"
'  The Gstin should be the same as the username in the jsonBody above.
http.SetRequestHeader "Gstin","09ABDC24212B1FK"
http.Accept = "application/json"

'  POST the JSON...
Dim resp As ChilkatHttpResponse
Set resp = http.PostJson2("http://ewb.wepgst.com/api/Authenticate","application/json",jsonBody.Emit())
If (http.LastMethodSuccess <> 1) Then
    Debug.Print http.LastErrorText
    Exit Sub
End If

Dim respStatusCode As Long
respStatusCode = resp.StatusCode
Debug.Print "response status code =" & respStatusCode
Debug.Print "response body:"
Debug.Print resp.BodyStr

If (respStatusCode <> 200) Then

    Debug.Print "Failed in some unknown way."
    Exit Sub
End If

'  When the response status code = 200, we'll have either
'  success response like this:
'   {"status":"1","authtoken":"...","sek":"..."}
' 
'  or a failed response like this:
' 
'  {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}

'  Load the response body into a JSON object.
Dim json As New ChilkatJsonObject
success = json.Load(resp.BodyStr)

Dim status As Long
status = json.IntOf("status")
Debug.Print "status = " & status

If (status <> 1) Then
    '  Failed.  Base64 decode the error
    ' {"status":"0","error":"eyJlcnJvckNvZGVzIjoiMTA4In0="}
    '  For an invalid password, the error is: {"errorCodes":"108"}
    Dim sbError As New ChilkatStringBuilder
    success = json.StringOfSb("error",sbError)
    success = sbError.Decode("base64","utf-8")
    Debug.Print "error: " & sbError.GetAsString()
    Exit Sub
End If

'  At this point, we know the request was entirely successful.
Dim authToken As String
authToken = json.StringOf("authtoken")

'  Decrypt the sek key using our app_key.
Dim crypt As New ChilkatCrypt2
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "ecb"
crypt.KeyLength = 256
crypt.SetEncodedKey app_key,"us-ascii"
crypt.EncodingMode = "base64"

Dim bdSek As New ChilkatBinData
success = bdSek.AppendEncoded(json.StringOf("sek"),"base64")
success = crypt.DecryptBd(bdSek)

'  bdSek now contains the decrypted symmetric encryption key...
'  We'll use it to encrypt the JSON payloads we send.

'  Let's persist our authtoken and decrypted sek (symmetric encryption key).
'  To send EWAY requests (such as to create an e-way bill), we'll just load
'  and use these pre-obtained credentials.
Dim jsonEwayAuth As New ChilkatJsonObject
success = jsonEwayAuth.UpdateString("authToken",authToken)
success = jsonEwayAuth.UpdateString("decryptedSek",bdSek.GetEncoded("base64"))
jsonEwayAuth.EmitCompact = 0

Dim fac As New CkFileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/ewayAuth.json",jsonEwayAuth.Emit(),"utf-8",0)

Debug.Print "Saved:"
Debug.Print jsonEwayAuth.Emit()

'  Sample output:
'  {
'    "authToken": "IBTeFtxNfVurg71LTzZ2r0xK7",
'    "decryptedSek": "5g1TyTie7yoslU3DrbYATa7mWyPazlODE7cEh5Vy4Ho="
'  }