(Xojo Plugin) Verify XML Digital Signature having KeyName

Demonstrates how to verify an XML digital signature where the KeyInfo part contains the KeyName element.
In this case, the public key is not specifically stored in the signed XML.
Rather, application specific information about the key is stored in the KeyName element.
This example uses the KeyName to find and matching public key.

This example requires Chilkat v9.5.0.69 or greater.

Chilkat Xojo Plugin Download

Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// The signed XML to be verified in this example contains the following:
// 
// <?xml version="1.0" encoding="UTF-8" standalone="no"?>
// <Envelope>
//   <Header>
//     <Security>
//     <ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#"><ds:SignedInfo><ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/><ds:SignatureMethod Algorithm="http://www.w3.org/2009/xmldsig11#dsa-sha256"/><ds:Reference URI="#abc"><ds:Transforms><ds:Transform Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/></ds:Transforms><ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/><ds:DigestValue>XTjDIHSEsDNTO9yn4cKtyXjRUjPFXkOQOLYI5mueZhk=</ds:DigestValue></ds:Reference></ds:SignedInfo><ds:SignatureValue>NXOIMevGCqFl0Dwtp2KkqkT05GRV8CjmHZ9LhFpt8/d7+lkIi7mITA==</ds:SignatureValue><ds:KeyInfo><ds:KeyName>dsaKey_123</ds:KeyName></ds:KeyInfo></ds:Signature></Security>
//   </Header>
//   <Body Id="abc">
//     <z:FooBar xmlns:z="https://www.example-code.com"/>
//   </Body>
// </Envelope>
// 

// The above XML is available at https://www.chilkatsoft.com/exampleData/signedUsingKeyName.xml
// First we'll fetch the signed XML:

Dim url As String
url = "https://www.chilkatsoft.com/exampleData/signedUsingKeyName.xml"
Dim http As New Chilkat.Http
Dim sbXml As New Chilkat.StringBuilder
Dim success As Boolean
success = http.QuickGetSb(url,sbXml)
If (success <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

Dim verifier As New Chilkat.XmlDSig

// Load the XML containing the signature to be verified.
success = verifier.LoadSignatureSb(sbXml)
If (success <> True) Then
    System.DebugLog(verifier.LastErrorText)
    Return
End If

// (The Chilkat XML Digital Signature API has the capability to handle XML documents with multiple signatures.
// We know in advance that this signed XML has just one Signature, so we leave the dsig.Selector property at the
// default value of 0.)

// Let's get the KeyInfo XML so we can then get the KeyName.
Dim xmlKeyInfo As Chilkat.Xml
xmlKeyInfo = verifier.GetKeyInfo()
If (verifier.LastMethodSuccess = False) Then
    System.DebugLog("There is no KeyInfo available in the Signature.")
    Return
End If

// Examine the XML:
System.DebugLog(xmlKeyInfo.GetXml())

// The KeyInfo XML that is returned looks like this:
// 
// 	<ds:KeyInfo>
// 	    <ds:KeyName>dsaKey_123</ds:KeyName>
// 	</ds:KeyInfo>
// 

// Get the KeyName.
Dim sbKeyName As New Chilkat.StringBuilder
success = sbKeyName.Append(xmlKeyInfo.GetChildContent("*:KeyName"))

// sbKeyName contains "dsaKey_123"
System.DebugLog(sbKeyName.GetAsString())

// The application now locates and loads the public key for verification
// based on the key name.  This example will do the following:
// If the key name equals "dsaKey_123", then load the DSA key from
// "qa_data/dsa/dsa1024_public.pem"
// 

If (sbKeyName.ContentsEqual("dsaKey_123",False) = False) Then
    System.DebugLog("I don't know this key...")
    Return
End If

// The DSA public key used in this example is available at:
// https://www.chilkatsoft.com/exampleData/dsa1024_public.zip
Dim pubKey As New Chilkat.PublicKey
success = pubKey.LoadFromFile("qa_data/dsa/dsa1024_public.pem")
If (success <> True) Then
    System.DebugLog(pubKey.LastErrorText)
    Return
End If

// Provide the DSA public key to the XML DSig verifier:
success = verifier.SetPublicKey(pubKey)

// Verify the signature
Dim bVerified As Boolean
bVerified = verifier.VerifySignature(True)
System.DebugLog("Signature verified = " + Str(bVerified))