(Xojo Plugin) GetChild* methods

Demonstrates several of the GetChild* methods.

The input XML, available at http://www.chilkatsoft.com/data/get_child.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

The output XML is this:

<abc b="pear" c="orange" a="130">Test</abc>

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

Dim xml As New Chilkat.Xml
Dim child As Chilkat.Xml

Dim success As Boolean
// The sample input XML is available at http://www.chilkatsoft.com/data/get_child.xml
success = xml.LoadXmlFile("get_child.xml")
If (success <> True) Then
    System.DebugLog(xml.LastErrorText)
    Return
End If

// The NumChildren property contains the number of direct
// child nodes.  Note: The child nodes under "xyz" are NOT
// direct children of "root".  Therefore, the "root" node has
// 7 direct children
System.DebugLog("NumChildren = " + Str(xml.NumChildren))

// Iterate over the direct children by index. The first child
// is at index 0.
Dim i As Int32
For i = 0 To xml.NumChildren - 1
    //  access the tag and content directly by index:
    System.DebugLog(Str(i) + ": " + xml.GetChildTagByIndex(i) + " : " + xml.GetChildContentByIndex(i))

Next
System.DebugLog("-----")

// Do the same as the above loop, but get the child node
// and access the Tag and Content properties:
For i = 0 To xml.NumChildren - 1
    child = xml.GetChild(i)
    System.DebugLog(Str(i) + ": " + child.Tag + " : " + child.Content)

Next
System.DebugLog("-----")

// Do the same as the above loop, but instead of creating
// a new object instance for each child, call GetChild2 to
// update the object's reference instead.
For i = 0 To xml.NumChildren - 1
    // Navigate to the Nth child.  
    success = xml.GetChild2(i)
    System.DebugLog(Str(i) + ": " + xml.Tag + " : " + xml.Content)
    // Navigate back up to the parent:
    success = xml.GetParent2()
Next
System.DebugLog("-----")

// Examine the result:
System.DebugLog(xml.GetXml())