(Xojo Plugin) WooCommerce OAuth 1.0a “one-legged” Authentication

Demonstrates how to use OAuth 1.0a "one legged" authentication with Woo Commerce.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Demonstrates how to do OAuth1 authentication for a Wordpress site using Woo Commerce.

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Prepare an OAuth 1.0 object for use with the Chilkat REST API.
Dim oauth1 As New Chilkat.OAuth1
oauth1.ConsumerKey = "WOO_COMMERCE_CONSUMER_KEY"
oauth1.ConsumerSecret = "WOO_COMMERCE_CONSUMER_SECRET"

// The signature method can be HMAC-SHA1 or HMAC-SHA256
oauth1.SignatureMethod = "HMAC-SHA256"

// The OauthUrl property will need to be updated each time a request is sent.
// The domain here must match the domain passed to the Connect method (below).
// The domain must be exact.  For example, "www.your-wordpress-site.com" vs. "your-wordpress-site.com".
// One might work while the other does not..
oauth1.OauthUrl = "http://your-wordpress-site.com/wc-api/v3/orders"

// The OAuthMethod property will be set automatically when the REST request is sent.
// Setting it here is not actually necessary.
oauth1.OauthMethod = "GET"

// Generate an initial nonce so that Chilkat knows the desired size of the nonce.
Dim success As Boolean
success = oauth1.GenNonce(32)

Dim rest As New Chilkat.Rest

// Tell the REST object to use the OAuth1 object for authentication.
// Also, indicate that the OAuth authentication parameters should be query parameters
// and not located within the Authorization header.
Dim bUseQueryParams As Boolean
bUseQueryParams = True
success = rest.SetAuthOAuth1(oauth1,bUseQueryParams)

// Make the initial connection (without sending a request yet) to the WooCommerce endpoint at your Wordpress blog.
Dim bTls As Boolean
bTls = False
Dim port As Int32
port = 80
Dim bAutoReconnect As Boolean
bAutoReconnect = True
success = rest.Connect("your-wordpress-site.com",port,bTls,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// Send a GET request to list orders.

// When the request is sent, the OAuth1 object's Timestamp and Nonce properties are automatically
// regenerated.  Also, the OAuth1 object's OauthMethod property is automatically set to the HTTP method
// used for the request (in this case it is "GET").
Dim responseJson As String
responseJson = rest.FullRequestNoBody("GET","/wc-api/v3/orders")
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// When successful, the response status code will equal 200.
If (rest.ResponseStatusCode <> 200) Then
    // Examine the request/response to see what happened.
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response body (if any): " + responseJson)
    System.DebugLog("---")
    System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
    System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
    Return
End If

System.DebugLog(responseJson)
System.DebugLog("Success.")