(Xojo Plugin) Walmart - Update bulk inventory

See Update bulk inventory for more information about this call.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Sends the following POST request:
// POST https://marketplace.walmartapis.com/v2/feeds?feedType=inventory

Dim success As Boolean
Dim url As String
url = "https://marketplace.walmartapis.com/v2/feeds?feedType=inventory"

Dim requestMethod As String
requestMethod = "POST"

// First we need to generate a signature for our request.
// The signature needs to be re-generated for each new Walmart HTTP request.
Dim authUtil As New Chilkat.AuthUtil

Dim wmConsumerId As String
wmConsumerId = "WALMART_CONSUMER_ID"
Dim wmPrivateKey As String
wmPrivateKey = "WALMART_PRIVATE_KEY"
Dim jsonStr As String
jsonStr = authUtil.WalmartSignature(url,wmConsumerId,wmPrivateKey,requestMethod)
If (authUtil.LastMethodSuccess <> True) Then
    System.DebugLog(authUtil.LastErrorText)
    Return
End If

// Build the HTTP POST request.
Dim req As New Chilkat.HttpRequest
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "/v2/feeds?feedType=inventory"
req.AddHeader "Accept","application/xml"

// The JSON returned by WalmartSignature contains the values to be used in the following
// header fields: WM_SEC.AUTH_SIGNATURE, WM_SEC.TIMESTAMP, and WM_QOS.CORRELATION_ID
Dim json As New Chilkat.JsonObject
success = json.Load(jsonStr)

req.AddHeader "WM_SVC.NAME","Walmart Marketplace"
req.AddHeader "WM_QOS.CORRELATION_ID",json.StringOf("correlation_id")
req.AddHeader "WM_SEC.TIMESTAMP",json.StringOf("timestamp")
req.AddHeader "WM_SEC.AUTH_SIGNATURE",json.StringOf("signature")
req.AddHeader "WM_CONSUMER.ID",wmConsumerId
//  Note: Make sure to replace "WALMART_CHANNEL_TYPE" with the actual value for your seller account...
req.AddHeader "WM_CONSUMER.CHANNEL.TYPE","WALMART_CHANNEL_TYPE"

// The body of the POST will contain XML.  In this example, we'll load the XML
// from a file.  The XML contains inventory data that looks something like this:

// <InventoryFeed xmlns="http://walmart.com/">
//   <InventoryHeader>
//       <version>1.4</version>
//   </InventoryHeader>
//   <inventory>
//       <sku>1068155</sku>
//       <quantity>
//           <unit>EACH</unit>
//           <amount>10</amount>
//       </quantity>
//       <fulfillmentLagTime>1</fulfillmentLagTime>
//   </inventory>
//   <inventory>
//       <sku>10210321</sku>
//       <quantity>
//           <unit>EACH</unit>
//           <amount>20</amount>
//       </quantity>
//       <fulfillmentLagTime>3</fulfillmentLagTime>
//   </inventory>
// </InventoryFeed>

success = req.AddFileForUpload2("inventory","qa_data/walmart/inventory.xml","application/xml")
If (success <> True) Then
    System.DebugLog(req.LastErrorText)
    Return
End If

Dim http As New Chilkat.Http
Dim resp As Chilkat.HttpResponse
resp = http.SynchronousRequest("marketplace.walmartapis.com",443,True,req)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

Dim xml As New Chilkat.Xml
success = xml.LoadXml(resp.BodyStr)

// A successful response should have a 200 response status
If (resp.StatusCode <> 200) Then
    System.DebugLog(xml.GetXml())
    System.DebugLog("Response Status Code: " + Str(resp.StatusCode))
    System.DebugLog("Failed.")

    Return
End If

// Show the XML response..
System.DebugLog(xml.GetXml())
System.DebugLog("--")
System.DebugLog("Success!")