Xojo Plugin

Unzip One File to a Stream

See more Zip Examples

Demonstrates how to unzip a particular file contained within a .zip archive to a Chilkat stream. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim zip As New Chilkat.Zip

// First open a .zip.
success = zip.OpenZip("qa_data/hamlet.zip")
If (success = False) Then
    System.DebugLog(zip.LastErrorText)
    Return
End If

// Find the entry to be unzipped to a stream..
Dim entry As New Chilkat.ZipEntry
success = zip.EntryMatching("*hamlet.xml",entry)
If (success = False) Then
    System.DebugLog(zip.LastErrorText)
    Return
End If

// There are three ways we can unzip (inflate) to a stream.
// 
// 1) Set a sink file on the stream object and call UnzipToStream synchronously.
//    This unzips to the stream's sink (which is to simply unzip to a file in the filesystem).
// 
// 2) Create a stream object and call UnzipToStreamAsync.  This starts the unzip in a background
//    thread (after Task.Run is called).  Your application can then read the unzipped (inflated) file
//    directly from the stream.
// 
// 3) (not shown in this example) Unzip to a stream object that is the source of something else.
//    

// ----------------------------------------------------------------
// Case 1: Unzip to a file by setting the sink of streamA to a file.
Dim streamA As New Chilkat.Stream
streamA.SinkFile = "qa_output/hamletA.xml"

success = entry.UnzipToStream(streamA)
If (success <> True) Then
    System.DebugLog(entry.LastErrorText)
    Return
End If

// Close the stream to close the output file.
success = streamA.WriteClose()

// ----------------------------------------------------------------
// Case 2a: Uzip to a stream asynchronously. 
Dim streamB As New Chilkat.Stream

Dim unzipTask As Chilkat.Task
unzipTask = entry.UnzipToStreamAsync(streamB)
If (entry.LastMethodSuccess <> True) Then
    System.DebugLog(entry.LastErrorText)
    Return
End If

// Start the background unzip thread.
success = unzipTask.Run()

// Read the stream.  (this is reading the unzipped file data)
Dim sb As New Chilkat.StringBuilder
While streamB.EndOfStream <> True
    // Each call to ReadSb appends to the contents of sb.
    success = streamB.ReadSb(sb)
Wend
success = sb.WriteFile("qa_output/hamletB.xml","utf-8",False)

System.DebugLog("Success.")

// ----------------------------------------------------------------
// Case 2b: Uzip to a stream asynchronously and emit output while reading. 
Dim streamC As New Chilkat.Stream

unzipTask = entry.UnzipToStreamAsync(streamC)
If (entry.LastMethodSuccess <> True) Then
    System.DebugLog(entry.LastErrorText)
    Return
End If

success = unzipTask.Run()

While streamC.EndOfStream <> True
    Dim s As String
    s = streamC.ReadString()
    System.DebugLog(s)
Wend

System.DebugLog("Success.")