(Xojo Plugin) Get Certificate As XML (and gets Signature Algorithm Identifier)

Demonstrates how to convert a certificate to XML such that the contents can easily be identified and accessed. Typically, the Chilkat Cert API provides properties and methods to access the most commonly needed pieces of information from a certificate. If a bit of information is not readily available then it can likely be retrieved from the XML representation. One such case is the certificate's signature algorithm identifier.

The basic internal format of a certificate is as follows (from section 4.1 of RFC 5280).

   Certificate  ::=  SEQUENCE  {
        tbsCertificate       TBSCertificate,
        signatureAlgorithm   AlgorithmIdentifier,
        signatureValue       BIT STRING  }

   TBSCertificate  ::=  SEQUENCE  {
        version         [0]  EXPLICIT Version DEFAULT v1,
        serialNumber         CertificateSerialNumber,
        signature            AlgorithmIdentifier,
        issuer               Name,
        validity             Validity,
        subject              Name,
        subjectPublicKeyInfo SubjectPublicKeyInfo,
        issuerUniqueID  [1]  IMPLICIT UniqueIdentifier OPTIONAL,
        subjectUniqueID [2]  IMPLICIT UniqueIdentifier OPTIONAL,
                             -- If present, version MUST be v2 or v3
        extensions      [3]  EXPLICIT Extensions OPTIONAL
                             -- If present, version MUST be v3
        }

Chilkat does not expect you to fully understand this notation and structure, but you can see that at a high level, the certificate is a sequence of three things, one after the other (a TBSCertifciate, an AlgorithmIdentifier, and a BIT STRING that is the signature). In XML format, it will look like this:

<sequence>
    <sequence>
        TBSCertificate goes here...
    </sequence>
    <sequence>
        <oid>1.2.840.113549.1.1.11</oid>
        <null />
    </sequence>
    <bits n="2048">3D20E895... 8DA307EC</bits>
</sequence>

The "oid" specifies the signature algorithm (such as sha256RSA), but it is an OID. In this case, the OID "1.2.840.113549.1.1.11" indicates "sha256WithRSAEncryption". (Google "1.2.840.113549.1.1.11" and you will find the 1st search result is http://www.alvestrand.no/objectid/1.2.840.113549.1.1.11.html. You can lookup any OID this way, to see what it means.)

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim socket As New Chilkat.Socket

Dim useTls As Boolean
useTls = True
Dim maxWaitMillisec As Int32
maxWaitMillisec = 20000
Dim tlsServerHost As String
tlsServerHost = "www.google.com"

Dim success As Boolean
success = socket.Connect(tlsServerHost,443,useTls,maxWaitMillisec)
If (success <> True) Then
    System.DebugLog(socket.LastErrorText)
    Return
End If

Dim cert As Chilkat.Cert
cert = socket.GetSslServerCert()
If (socket.LastMethodSuccess <> True) Then
    System.DebugLog(socket.LastErrorText)
    Return
End If

// Close the connection with the server
// Wait a max of 20 millsec for a clean TLS shutdown.  
success = socket.Close(20)

// Examine the server cert in XML format
Dim certXml As String
certXml = cert.ExportCertXml()
System.DebugLog(certXml)

// Let's parse the XML to get the signature algorithm identifier.
Dim xml As New Chilkat.Xml
success = xml.LoadXml(certXml)

// The 2nd child is at index 1.
Dim algId As Chilkat.Xml
algId = xml.GetChild(1)
Dim oid As String
oid = algId.GetChildContent("oid")
System.DebugLog("Signature Algorithm OID = " + oid)