Xojo Plugin

SSL Server Example

See more Socket/SSL/TLS Examples

Demonstrates how to create an SSL socket for accepting connections. This example is *very* simple in that it will create an SSL socket for accepting a single connection. It will read a message from the client, send a reply, and exit. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim listenSslSocket As New Chilkat.Socket

// An SSL server needs a digital certificate.  This example loads it from a PFX file.

// Create an instance of a certificate store object, load a PFX file,
// locate the certificate we need, and use it.
// (a PFX file may contain more than one certificate.)
Dim certStore As New Chilkat.CertStore
// The 1st argument is the filename, the 2nd arg is the 
// PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success = False) Then
    System.DebugLog(certStore.LastErrorText)
    Return
End If

// Find the certificate to be used for SSL:
Dim jsonCN As New Chilkat.JsonObject
success = jsonCN.UpdateString("CN","example.com")

Dim cert As New Chilkat.Cert
success = certStore.FindCert(jsonCN,cert)
If (success = False) Then
    System.DebugLog(certStore.LastErrorText)
    Return
End If

// Use the certificate:
success = listenSslSocket.InitSslServer(cert)
If (success = False) Then
    System.DebugLog(listenSslSocket.LastErrorText)
    Return
End If

// Bind and listen on a port:
Dim myPort As Int32
myPort = 8123
// Allow for a max of 5 queued connect requests.
Dim backLog As Int32
backLog = 5
success = listenSslSocket.BindAndListen(myPort,backLog)
If (success = False) Then
    System.DebugLog(listenSslSocket.LastErrorText)
    Return
End If

// If accepting an SSL/TLS connection, the SSL handshake is part of the connection
// establishment process. This involves a few back-and-forth messages between the 
// client and server to establish algorithms and a shared key to create the secure 
// channel. The sending and receiving of these messages are governed by the 
// MaxReadIdleMs and MaxSendIdleMs properties. If these properties are set to 0 
// (and this is the default unless changed by your application), then the 
// AcceptNext can hang indefinitely during the SSL handshake process. 
// Make sure these properties are set to appropriate values before calling AcceptNext.

// Set a 10 second max for waiting to read/write.  This is for the SSL/TLS handshake establishment.
listenSslSocket.MaxReadIdleMs = 10000
listenSslSocket.MaxSendIdleMs = 10000

// Accept a single client connection and establish the secure SSL/TLS channel:
Dim maxWaitMillisec As Int32
maxWaitMillisec = 20000
Dim clientSock As New Chilkat.Socket
success = listenSslSocket.AcceptNext(maxWaitMillisec,clientSock)
If (success = False) Then
    System.DebugLog(listenSslSocket.LastErrorText)
    Return
End If

// The client (in this example) is going to send a "Hello Server! -EOM-" 
// message.  Read it:
Dim receivedMsg As String
receivedMsg = clientSock.ReceiveUntilMatch("-EOM-")
If (clientSock.LastMethodSuccess = False) Then
    System.DebugLog(clientSock.LastErrorText)
    Return
End If

System.DebugLog(receivedMsg)

// Send a "Hello Client! -EOM-" message:
success = clientSock.SendString("Hello Client! -EOM-")
If (success = False) Then
    System.DebugLog(clientSock.LastErrorText)
    Return
End If

// Close the connection with the client
// Wait a max of 20 seconds (20000 millsec)
success = clientSock.Close(20000)