Xojo Plugin

SSH Remote Shell with Multiple Commands

Demonstrates running several commands one after another in a single remote shell session, retrieving each command's output separately. No PTY is requested, so each command is followed by an echoed marker that signals where its output ends.

Background: Interleaving commands and reads in one shell requires a way to know where each command's output stops. An interactive session would use the shell prompt, but without a PTY the shell is non-interactive and never prints one — so the dependable technique is to append echo SOME_MARKER to each command and read up to that marker. Retrieving the text also clears the receive buffer, which matters here: if a marker were left buffered, the next receive would match it immediately and return the wrong output.

Chilkat Xojo Plugin Downloads

Download Chilkat for Xojo Plugin

Xojo Plugin

Dim success As Boolean
success = False

//  This example requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  Demonstrates running several commands one after another in a single remote shell session,
//  retrieving each command's output separately.
//  
//  No PTY is requested, so the shell runs non-interactively and never prints a command prompt.
//  Because there is no prompt to synchronize on, each command is followed by an "echo" of a
//  unique marker, and the output is read up to that marker.

Dim ssh As New Chilkat.Ssh

Dim hostname As String
hostname = "ssh.example.com"
Dim port As Int32
port = 22
success = ssh.Connect(hostname,port)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  Normally you would not hard-code the password in source.  You should instead obtain it
//  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String
password = "mySshPassword"

success = ssh.AuthenticatePw("mySshLogin",password)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

Dim channelNum As Int32
channelNum = ssh.OpenSessionChannel()
If (channelNum < 0) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  Start a shell WITHOUT requesting a PTY.  Without a PTY the shell sees it is connected to a
//  raw data pipe and enters non-interactive mode: it suppresses the command prompt, does not
//  echo typed commands back, and skips interactive login scripts.  The output is therefore
//  clean and easily parseable -- but because no prompt is ever sent, code must not wait for
//  one.  Instead, have each command print a predictable marker, or wait for EOF / channel close.
success = ssh.SendReqShell(channelNum)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  IMPORTANT: Set a read timeout before receiving until a match.  ReadTimeoutMs defaults to 0,
//  which means no limit -- without it, this call waits forever if the received data never
//  contains a match.
ssh.ReadTimeoutMs = 15000

Dim caseSensitive As Boolean
caseSensitive = True

//  ---- 1st command: change directory ----
success = ssh.ChannelSendString(channelNum,"cd /tmp; echo END_OF_CMD_1" + EndOfLine.Unix,"utf-8")
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

success = ssh.ChannelReceiveUntilMatch(channelNum,"END_OF_CMD_1","utf-8",caseSensitive)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  Retrieving the text also clears the receive buffer, which matters: if the next marker were
//  left in the buffer, the following receive would match immediately.
Dim cmdOutput As String
cmdOutput = ssh.GetReceivedText(channelNum,"utf-8")
If (ssh.LastMethodSuccess = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

System.DebugLog(cmdOutput)

//  ---- 2nd command: directory listing ----
success = ssh.ChannelSendString(channelNum,"ls; echo END_OF_CMD_2" + EndOfLine.Unix,"utf-8")
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

success = ssh.ChannelReceiveUntilMatch(channelNum,"END_OF_CMD_2","utf-8",caseSensitive)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

cmdOutput = ssh.GetReceivedText(channelNum,"utf-8")
If (ssh.LastMethodSuccess = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

System.DebugLog(cmdOutput)

//  ---- 3rd command: long listing, then finish the session ----
success = ssh.ChannelSendString(channelNum,"ls -l" + EndOfLine.Unix,"utf-8")
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  No more input will be sent.
success = ssh.ChannelSendEof(channelNum)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

success = ssh.ChannelReceiveToClose(channelNum)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

cmdOutput = ssh.GetReceivedText(channelNum,"utf-8")
If (ssh.LastMethodSuccess = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

System.DebugLog(cmdOutput)

ssh.Disconnect