Xojo Plugin

SSH Auth Failure Reason (AuthenticatePwPk)

Demonstrates how to determine why authentication failed when a server requires both a password and a private key. If AuthenticatePwPk fails, GetLastJsonData returns diagnostic JSON whose authResult and authFailReason members reveal which factor was at fault.

Background: With multi-factor SSH, a plain failure is ambiguous — the key could be wrong, the password could be wrong, or both. The diagnostic JSON resolves that: it reports Key is incorrect when the key fails, or a partialAuthResult showing the key succeeded before Password is incorrect. Note the ordering consequence: if the key is rejected, authentication never reaches the password check, so you cannot yet know whether the password is also wrong. Passwords and passphrases are never included in this JSON, so it is safe to log.

Chilkat Xojo Plugin Downloads

Download Chilkat for Xojo Plugin

Xojo Plugin

Dim success As Boolean
success = False

//  This example requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  Demonstrates how to determine why authentication failed when a server requires BOTH a
//  password and a private key.  Was the private key wrong, or the password?

//  Load the private key used for authentication.
Dim key As New Chilkat.SshKey

//  The key password is not hard-coded in a real application; obtain it from a secure source.
key.Password = "myKeyPassword"

Dim privKeyText As String
privKeyText = key.LoadText("qa_data/my_private_key_file")
If (key.LastMethodSuccess = False) Then
    System.DebugLog(key.LastErrorText)
    Return
End If

success = key.FromOpenSshPrivateKey(privKeyText)
If (success = False) Then
    System.DebugLog(key.LastErrorText)
    Return
End If

Dim ssh As New Chilkat.Ssh
Dim port As Int32
port = 22
success = ssh.Connect("ssh.example.com",port)
If (success = False) Then
    System.DebugLog(ssh.LastErrorText)
    Return
End If

//  Normally you would not hard-code the password in source.  You should instead obtain it
//  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String
password = "mySshPassword"

//  Authenticate using both a password and a private key.
success = ssh.AuthenticatePwPk("mySshLogin",password,key)
If (success) Then
    System.DebugLog("Authentication is successful!")
    Return
End If

//  Authentication failed.  The diagnostic JSON explains which factor was at fault.
Dim json As New Chilkat.JsonObject
ssh.GetLastJsonData json
json.EmitCompact = False

//  If the key is correct but the password is wrong:
//  {
//    "public_key_type": "rsa",
//    "partialAuthResult": "publickey success. continue to authenticate with password...",
//    "authResult": "failed",
//    "authFailReason": "Password is incorrect"
//  }
//  
//  If the key is incorrect.  Whether the password is also wrong is unknown, because
//  authentication never got far enough to check it:
//  {
//    "public_key_type": "rsa",
//    "authResult": "failed",
//    "authFailReason": "Key is incorrect"
//  }

System.DebugLog("authResult: " + json.StringOf("authResult"))
System.DebugLog("authFailReason: " + json.StringOf("authFailReason"))