(Xojo Plugin) SOAP Web Service (HTTP POST)

Demonstrates how to call PostXml to call a SOAP web service.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// --------------------------------------------------------------------------------
// Also see Chilkat's Online WSDL Code Generator
// to generate code and SOAP Request and Response XML for each operation in a WSDL.
// --------------------------------------------------------------------------------

// This example uses a live web service at:
// http://www.webservicex.net/uklocation.asmx
// It gets the UK town,Postcode and County by Postcode(First Section of Post Code)

// The SOAP XML will look like this:
// <?xml version="1.0" encoding="utf-8"?>
// <soap:Envelope xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
//   <soap:Body>
//     <GetUKLocationByPostCode xmlns="http://www.webserviceX.NET">
//       <PostCode>string</PostCode>
//     </GetUKLocationByPostCode>
//   </soap:Body>
// </soap:Envelope>

// For this example's sake, we'll load the XML from a file.  We'll test using PostCode "E3".  
// The SOAP XML for this example may be downloaded from:
// http://www.chilkatsoft.com/testData/ukPostCodeSoap.xml
Dim xml As New Chilkat.Xml
Dim success As Boolean
success = xml.LoadXmlFile("ukPostCodeSoap.xml")
If (success <> True) Then
    System.DebugLog(xml.LastErrorText)
    Return
End If

Dim strXml As String
strXml = xml.GetXml()

Dim responseStatusCode As Int32
Dim http As New Chilkat.Http

// We'll need to add this in the HTTP header:
// SOAPAction: "http://www.webserviceX.NET/GetUKLocationByPostCode"
http.SetRequestHeader "SOAPAction","http://www.webserviceX.NET/GetUKLocationByPostCode"

// Some services expect the content-type in the HTTP header to be "application/xml" while
// other expect text/xml.  The default sent by Chilkat is "application/xml", but this web service
// expects "text/xml".  Therefore, change the content-type:
http.SetRequestHeader "Content-Type","text/xml; charset=utf-8"

// The endpoint for this soap service is:
Dim endPoint As String
endPoint = "http://www.webservicex.net/uklocation.asmx"

// Note: This particular web service was live and functioning at the time this example
// was written.  It is possible that as time progresses, this web service will no longer
// be availble...
Dim resp As Chilkat.HttpResponse
resp = http.PostXml(endPoint,strXml,"utf-8")
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    System.DebugLog("LastHeader:")
    System.DebugLog(http.LastHeader)
    Return
End If

responseStatusCode = resp.StatusCode
// You may wish to verify that the responseStatusCode equals 200...
System.DebugLog("Response Status Code: " + Str(responseStatusCode))

// You may examine the exact HTTP header sent with the POST like this:
System.DebugLog("LastHeader:")
System.DebugLog(http.LastHeader)

// Examine the XML returned by the web service:
System.DebugLog("XML Response:")
Dim xmlResp As New Chilkat.Xml
success = xmlResp.LoadXml(resp.BodyStr)
System.DebugLog(xmlResp.GetXml())

// Use this online tool to generate parsing code from response XML: 
// Generate Parsing Code from XML