Xojo Plugin

SharePoint Rest API using OAuth

See more OAuth2 Examples

Demonstrates how to get an OAuth2 access token for the SharePoint REST API. Xojo Plugin

Dim success As Boolean
success = False

// To further clarify, see OAuth 2.0 Authorization Flow

Dim oauth2 As New Chilkat.OAuth2

// The ListenPort should match the port in your localhost Reply URL of your Azure AD app.
// Your Reply URL must be exactly "http://localhost:LISTEN_PORT/"
//    * Do not use "https"
//    * Make sure the ending "/" is included.
//    * You may choose any port number that doesn't collide with anything else.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/TENANT_ID/oauth2/authorize"
oauth2.TokenEndpoint = "https://login.windows.net/TENANT_ID/oauth2/token?api-version=1.0"

// Replace these with actual values.
// Use the application ID
oauth2.ClientId = "CLIENT_ID"
// Use the password
oauth2.ClientSecret = "CLIENT_SECRET"

oauth2.CodeChallenge = False

oauth2.Scope = "openid"
oauth2.Resource = "https://graph.microsoft.com/"

oauth2.IncludeNonce = True
oauth2.ResponseMode = "form_post"
oauth2.ResponseType = "id_token+code"

// Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess = False) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

System.DebugLog("url = " + url)

// Launch the default browser on the system and navigate to the url.
// The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = False) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

// Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Int32
numMsWaited = 0
While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Wend

// If the browser does not respond within the specified time, AuthFlowState will be:
// 
// 1: Waiting for Redirect – The OAuth2 background thread is waiting for the browser's redirect request.
// 2: Waiting for Final Response – The thread is awaiting the final access token response.
// In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    System.DebugLog("No response from the browser!")
    Return
End If

// Check AuthFlowState to determine if authorization was granted, denied, or failed:
// 
// 3: Success – OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
// 4: Access Denied – OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
// 5: Failure – OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    System.DebugLog("OAuth2 failed to complete.")
    System.DebugLog(oauth2.FailureInfo)
    Return
End If

If (oauth2.AuthFlowState = 4) Then
    System.DebugLog("OAuth2 authorization was denied.")
    System.DebugLog(oauth2.AccessTokenResponse)
    Return
End If

If (oauth2.AuthFlowState <> 3) Then
    System.DebugLog("Unexpected AuthFlowState:" + Str(oauth2.AuthFlowState))
    Return
End If

System.DebugLog("OAuth2 authorization granted!")
System.DebugLog("Access Token = " + oauth2.AccessToken)