(Xojo Plugin) SharePoint -- Check In a File

In SharePoint, you can check out a file to make sure nobody can change it before you update it. After updating, you can check in the file. This example shows how to check in a SharePoint file.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

// If SharePoint Windows classic authentication is used, then set the 
// Login, Password, LoginDomain, and NtlmAuth properties.
http.Login = "SHAREPOINT_USERNAME"
http.Password = "SHAREPOINT_PASSWORD"
http.LoginDomain = "SHAREPOINT_NTLM_DOMAIN"
http.NtlmAuth = True

// The more common case is to use SharePoint Online authentication (via the SPOIDCRL cookie).
// If so, do not set Login, Password, LoginDomain, and NtlmAuth, and instead
// establish the cookie as shown at SharePoint Online Authentication

// This example will check in the file named "penguins2.jpg" 
// which is located in the "/Documents" folder.

Dim req As New Chilkat.HttpRequest
req.HttpVerb = "POST"
// Note that our path uses GetFileByServerRelativeUrl and not GetFolderByServerRelativeUrl
// Also, if your Sharepoint site is within a site collection, the URL is formatted like this (where "teamA" is the name of the site)
// /sites/teamA/_api/web/GetFileByServerRelativeUrl('/sites/teamA/Documents/penguins2.jpg')/CheckIn(comment='Comment',checkintype=0)
req.Path = "/_api/web/GetFileByServerRelativeUrl('/Documents/penguins2.jpg')/CheckIn(comment='Comment',checkintype=0)"

// We need to add a form digest value in the X-RequestDigest header field.
// See this example for details on
// how to get (and cache) a form digest value
req.AddHeader "X-RequestDigest","SHAREPOINT_FORM_DIGEST"

// Send the POST using HTTPS (TLS). Port 443 is the default port for https.
Dim bUseTls As Boolean
bUseTls = True
Dim resp As Chilkat.HttpResponse
resp = http.SynchronousRequest("SHAREPOINT_HTTPS_DOMAIN",443,bUseTls,req)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

// The response body contains XML.
Dim xml As New Chilkat.Xml
Dim success As Boolean
success = xml.LoadXml(resp.BodyStr)

If (resp.StatusCode <> 200) Then
    System.DebugLog("Response status code = " + Str(resp.StatusCode))
    System.DebugLog(xml.GetXml())
    System.DebugLog("Failed")

    Return
End If

// Show the successful XML response.
System.DebugLog(xml.GetXml())
System.DebugLog("Success.")

// A successful XML response looks like this:
// <?xml version="1.0" encoding="utf-8" ?>
// <d:CheckIn xmlns:d="http://schemas.microsoft.com/ado/2007/08/dataservices" 	
// 	xmlns:m="http://schemas.microsoft.com/ado/2007/08/dataservices/metadata"
// 	xmlns:georss="http://www.georss.org/georss" 
// 	xmlns:gml="http://www.opengis.net/gml" m:null="true" />
//