Xojo Plugin

ScMinidriver - List Certificates on a Smart Card or USB Token

See more ScMinidriver Examples

Gets a list of certificates contained on a smart card or USB token. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim scmd As New Chilkat.ScMinidriver

// Reader names (smart card readers or USB tokens) can be discovered
// via PCSC List Readers or PCSC Find Smart Cards
Dim readerName As String
readerName = "SCM Microsystems Inc. SCR33x USB Smart Card Reader 0"
success = scmd.AcquireContext(readerName)
If (success = False) Then
    System.DebugLog(scmd.LastErrorText)
    Return
End If

Dim stCerts As New Chilkat.StringTable

// We can choose one of the following items of information to get for each certificate:
// "subjectDN" -- Return the full distinguished name of the cert.
// "subjectDN_withTags" -- Same as above, but in a format that includes the subject part tags, such as the "CN=" in "CN=something"
// "subjectCN" -- Return just the common name part of the certificate's subject.
// "serial" -- Return the certificate serial number.
// "serial:issuerCN" -- return the certificate serial number + the issuer's common name, delimited with a colon char.
Dim certPart As String
certPart = "subjectCN"

success = scmd.ListCerts(certPart,stCerts)
If (success = False) Then
    System.DebugLog(scmd.LastErrorText)
    Return
End If

Dim numCerts As Int32
numCerts = stCerts.Count
Dim i As Int32
i = 0
While i < numCerts
    System.DebugLog(Str(i) + ": " + stCerts.StringAt(i))
    i = i + 1
Wend

// Delete the context when finished with the card.
success = scmd.DeleteContext()
If (success = False) Then
    System.DebugLog(scmd.LastErrorText)
End If