Xojo Plugin

RSA Sign with PKCS8 Encrypted Key

See more RSA Examples

Demonstrates how to load a private key from an encrypted PKCS8 file and create an RSA digital signature (and then verify it). Xojo Plugin

Dim success As Boolean
success = False

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim privKey As New Chilkat.PrivateKey

// Load the private key from an RSA PEM file:
success = privKey.LoadAnyFormatFile("raul_privateKey.key","a0123456789")
If (success = False) Then
    System.DebugLog(privKey.LastErrorText)
    Return
End If

Dim rsa As New Chilkat.Rsa

// Import the private key into the RSA component:
success = rsa.UsePrivateKey(privKey)
If (success = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// This example will sign a string, and receive the signature
// in a hex-encoded string.  Therefore, set the encoding mode
// to "hex":
rsa.EncodingMode = "hex"

Dim strData As String
strData = "This is the string to be signed."

// Sign the string using the sha256 hash algorithm.
// Other valid choices are sha1, sha384, sha512 and others.
Dim hexSig As String
hexSig = rsa.SignStringENC(strData,"sha256")
If (rsa.LastMethodSuccess = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

System.DebugLog(hexSig)

// Now verify with the public key.
// This example shows how to use the public key from 
// a digital certificate (.cer file)
Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("raul_publicKey.cer")
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

Dim pubKey As New Chilkat.PublicKey
success = cert.GetPublicKey(pubKey)

Dim rsa2 As New Chilkat.Rsa
success = rsa2.UsePublicKey(pubKey)
If (success = False) Then
    System.DebugLog(rsa2.LastErrorText)
    Return
End If

// Verify the signature against the original data:
rsa2.EncodingMode = "hex"
success = rsa2.VerifyStringENC(strData,"sha256",hexSig)
If (success = False) Then
    System.DebugLog(rsa2.LastErrorText)
    Return
End If

System.DebugLog("Signature verified!")

// Verify with incorrect data:
success = rsa2.VerifyStringENC("something else","sha256",hexSig)
If (success <> True) Then
    System.DebugLog("Signature not verified! (which was expected in this case)")
Else
    System.DebugLog("Hmmm... that's not right...")
End If