(Xojo Plugin) Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

1. Input data is hashed using the hashing algorithm specified.
2. The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
3. The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

1. The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
2. The PKCS v1.5 padded data is RSA signed and the signature is returned.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim pkey As New Chilkat.PrivateKey

// Load the private key from an RSA PEM file:
Dim success As Boolean
success = pkey.LoadPemFile("private.pem")
If (success <> True) Then
    System.DebugLog(pkey.LastErrorText)
    Return
End If

Dim pkeyXml As String
// Get the private key in XML format:
pkeyXml = pkey.GetXml()

Dim rsa As New Chilkat.Rsa

// Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> True) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// This example will sign a string, and receive the signature
// in a hex-encoded string.  Therefore, set the encoding mode
// to "hex":
rsa.EncodingMode = "hex"

Dim strData As String
strData = "secret"

// Create an OpenSSL style signature:
Dim hexSig As String
hexSig = rsa.OpenSslSignStringENC(strData)

System.DebugLog(hexSig)

// Recover the data using the corresponding public key:
Dim pubkey As New Chilkat.PublicKey

// Load the public key from a PEM file:
success = pubkey.LoadFromFile("public.pem")
If (success <> True) Then
    System.DebugLog(pubkey.LastErrorText)
    Return
End If

Dim pubkeyXml As String
// Get the public key in XML format:
pubkeyXml = pubkey.GetXml()

Dim rsa2 As New Chilkat.Rsa

// Import the public key into the RSA component:
success = rsa2.ImportPublicKey(pubkeyXml)
If (success <> True) Then
    System.DebugLog(rsa2.LastErrorText)
    Return
End If

rsa2.EncodingMode = "hex"

// Recover the original data.
Dim originalData As String
originalData = rsa2.OpenSslVerifyStringENC(hexSig)

System.DebugLog(originalData)