(Xojo Plugin) About RSA Public/Private Keys

This example provides some additional information for understanding public/private key pairs. In demonstrates how a private key is a superset of the public key. A public key contains the modulus and exponent. The matching private key also contains the modulus and exponent, but also contains the additional private key parts.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

Dim success As Boolean
success = False

Dim cert As New Chilkat.Cert

// Load a digital certificate.
success = cert.LoadFromFile("digitalCert.cer")
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

// A .cer file does not contain the private key.  It should contain
// the public key...
Dim pubKey As New Chilkat.PublicKey
success = cert.GetPublicKey(pubKey)

// Let's have a look at it (in XML format).
System.DebugLog("Public Key from Certificate:")
System.DebugLog(pubKey.GetXml())

// An RSA public key consists of a modulus and exponent.

// An RSA private key includes both the modulus and exponent,
// as well as other "big" numbers: P, Q, D, etc.

// Let's load an RSA private key from a DER-encoded file:
Dim privKey As New Chilkat.PrivateKey

success = privKey.LoadAnyFormatFile("PrivateKey.key","")
If (success <> True) Then
    System.DebugLog(privKey.LastErrorText)
    Return
End If

// If this private key is the matching half to the public key from
// the certificate, then the modulus and exponent should
// be identical.  (Thus, a "private key" really contains both the public part as well as the private parts...).
System.DebugLog("Private Key from DER:")
System.DebugLog(privKey.GetXml())