(Xojo Plugin) RSA Encrypt Hash using SHA256 hash function and SHA1 mask function

Note: This example requires a feature introduced in Chilkat v9.5.0.66

How can this Javascript be duplicated using Chilkat?

function a(e, t) {
                var r = s.pki.publicKeyFromPem(e)
                  , n = r.encrypt(t, "RSA-OAEP", {
                    md: s.md.sha256.create(),
                    mgf1: {
                        md: s.md.sha1.create()
                    }
                });
                return s.util.encode64(n)
            }

Note: The OAEP padding uses random bytes in the padding, and therefore each time encryption happens, even using the same data and key, the result will be different -- but still valid. One should not expect to get the same output.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

Dim success As Boolean
success = False

// Note: This example requires a feature introduced in Chilkat v9.5.0.66

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim pubkey As New Chilkat.PublicKey

Dim sbPem As New Chilkat.StringBuilder
Dim bCrlf As Boolean
bCrlf = True
success = sbPem.AppendLine("-----BEGIN PUBLIC KEY-----",bCrlf)
success = sbPem.AppendLine("MIIBIjANBgkqhkiG9w0BAQEFAAOCAQ8AMIIBCgKCAQEA33TqqLR3eeUmDtHS89qF",bCrlf)
success = sbPem.AppendLine("3p4MP7Wfqt2Zjj3lZjLjjCGDvwr9cJNlNDiuKboODgUiT4ZdPWbOiMAfDcDzlOxA",bCrlf)
success = sbPem.AppendLine("04DDnEFGAf+kDQiNSe2ZtqC7bnIc8+KSG/qOGQIVaay4Ucr6ovDkykO5Hxn7OU7s",bCrlf)
success = sbPem.AppendLine("Jp9TP9H0JH8zMQA6YzijYH9LsupTerrY3U6zyihVEDXXOv08vBHk50BMFJbE9iwF",bCrlf)
success = sbPem.AppendLine("wnxCsU5+UZUZYw87Uu0n4LPFS9BT8tUIvAfnRXIEWCha3KbFWmdZQZlyrFw0buUE",bCrlf)
success = sbPem.AppendLine("f0YN3/Q0auBkdbDR/ES2PbgKTJdkjc/rEeM0TxvOUf7HuUNOhrtAVEN1D5uuxE1W",bCrlf)
success = sbPem.AppendLine("SwIDAQAB",bCrlf)
success = sbPem.AppendLine("-----END PUBLIC KEY-----",bCrlf)

// Load the public key object from the PEM. 
success = pubkey.LoadFromString(sbPem.GetAsString())
If (success = False) Then
    System.DebugLog(pubkey.LastErrorText)
    Return
End If

Dim originalData As String
originalData = "This is the original data to be SHA-256 hashed and RSA encrypted."

// First we SHA-256 hash the original data to get the hash in base64 format:
Dim crypt As New Chilkat.Crypt2
crypt.HashAlgorithm = "SHA-256"
crypt.EncodingMode = "base64"
Dim hashBase64 As String
hashBase64 = crypt.HashStringENC(originalData)

// Setup RSA to use OAEP padding with SHA-1 for the mask function.
Dim rsa As New Chilkat.Rsa
rsa.PkcsPadding = True
rsa.OaepHash = "SHA1"
success = rsa.UsePublicKey(pubkey)
rsa.EncodingMode = "base64"

// Starting in v9.5.0.66, we can provide a binary encoding mode, such as "base64", "hex", "base64url", etc.
// for the Charset property.   The Charset property was previously limited to character encodings, such as
// "utf-8", "iso-8859-1", etc.  If a binary encoding is used, then the string passed in is decoded to the binary
// bytes as indicated.  (If an actual charset, such as "utf-8" is used, then the input string is converted to the
// byte representation of the charset, and then encrypted.)

// Given that a hash is composed of non-text binary bytes, we'll set the Charset property equal to "base64" 
// (because we have the base64 hash from above).
rsa.Charset = "base64"

// Note: The OAEP padding uses random bytes in the padding, and therefore each time encryption happens,
// even using the same data and key, the result will be different --  but still valid.  One should not expect
// to get the same output.
Dim bUsePrivateKey As Boolean
bUsePrivateKey = False
Dim encryptedStr As String
encryptedStr = rsa.EncryptStringENC(hashBase64,bUsePrivateKey)
If (rsa.LastMethodSuccess = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

System.DebugLog("Base64 RSA encrypted output: " + encryptedStr)