Xojo Plugin

Payeezy HMAC Computation

See more HTTP Misc Examples

Demonstrates how to calculate the HMAC for a Payeezy REST request. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2
Dim prng As New Chilkat.Prng

// An API key such as y6pWAJNyJyjGv66IsVuWnklkKUPFbb0a
Dim apiKey As String
apiKey = "my_api_key"
// An API secret such as 86fbae7030253af3cd15faef2a1f4b67353e41fb6799f576b5093ae52901e6f7
Dim apiSecret As String
apiSecret = "my_api_secret"
// A token such as fdoa-a480ce8951daa73262734cf102641994c1e55e7cdf4c02b6
Dim token As String
token = "my_merchant_token"

// The nonce is a random number (bytes), something like "6057786719490086000"
Dim nonce As String
nonce = prng.GenRandom(8,"decimal")
System.DebugLog("nonce = " + nonce)

Dim dtNow As New Chilkat.CkDateTime
success = dtNow.SetFromCurrentSystemTime()
Dim sbTimestamp As New Chilkat.StringBuilder
// Get the epoch timestamp in seconds
success = sbTimestamp.Append(dtNow.GetAsUnixTimeStr(False))
// Change it to milliseconds
success = sbTimestamp.Append("000")
// The timestamp is a number similar to this: 1546011905000 (which is a timestamp taken on 28-Dec-2018).
Dim timestamp As String
timestamp = sbTimestamp.GetAsString()
System.DebugLog("timestamp = " + timestamp)

// Generate the following JSON request body:
// 	{
// 	  "merchant_ref": "Astonishing-Sale",
// 	  "transaction_type": "authorize",
// 	  "method": "token",
// 	  "amount": "200",
// 	  "currency_code": "USD",
// 	  "token": {
// 	    "token_type": "FDToken",
// 	    "token_data": {
// 	      "type": "visa",
// 	      "value": "2537446225198291",
// 	      "cardholder_name": "JohnSmith",
// 	      "exp_date": "1030",
// 	      "special_payment": "B"
// 	    }
// 	  }
// 	}

Dim json As New Chilkat.JsonObject
success = json.UpdateString("merchant_ref","Astonishing-Sale")
success = json.UpdateString("transaction_type","authorize")
success = json.UpdateString("method","token")
success = json.UpdateString("amount","200")
success = json.UpdateString("currency_code","USD")
success = json.UpdateString("token.token_type","FDToken")
success = json.UpdateString("token.token_data.type","visa")
success = json.UpdateString("token.token_data.value","2537446225198291")
success = json.UpdateString("token.token_data.cardholder_name","JohnSmith")
success = json.UpdateString("token.token_data.exp_date","1030")
success = json.UpdateString("token.token_data.special_payment","B")

// string hashData = apiKey + nonce + timestamp + token + jsonString;
Dim sbHmacData As New Chilkat.StringBuilder
success = sbHmacData.Append(apiKey)
success = sbHmacData.Append(nonce)
success = sbHmacData.Append(timestamp)
success = sbHmacData.Append(token)
success = sbHmacData.Append(json.Emit())

// HMAC the data to produce a hex string.
crypt.EncodingMode = "hexlower"
crypt.MacAlgorithm = "hmac"
success = crypt.SetMacKeyString(apiSecret)
crypt.HashAlgorithm = "sha256"
crypt.Charset = "utf-8"
Dim hexHash As String
hexHash = crypt.MacStringENC(sbHmacData.GetAsString())

// Now base64 encode the hex string:
Dim sbBase64Hash As New Chilkat.StringBuilder
success = sbBase64Hash.Append(hexHash)
success = sbBase64Hash.Encode("base64","utf-8")

System.DebugLog("This is the Authorization header to be sent with the payeezy request:")
System.DebugLog("Authorization: " + sbBase64Hash.GetAsString())