Xojo Plugin Requires Chilkat v11.0.0+
Outlook -- Copy Mail Folder and Contents to another Mail Folder

Copy a mailfolder and its contents to another mailfolder.
Chilkat Xojo Plugin Downloads

Xojo Plugin
Dim success As Boolean
success = False

//  This example requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

//  Use your previously obtained access token here:
http.AuthToken = "MICROSOFT_GRAPH_ACCESS_TOKEN"

//  This example will copy /Inbox/abc/subFolderA and its contents to /Inbox/xyz
//  We'll need the folder ids for both source and destination folders..

//  Get the folder IDs from the folder map created by this example 
Dim htFolderMap As New Chilkat.Hashtable
Dim sbMap As New Chilkat.StringBuilder
success = sbMap.LoadFile("qa_data/outlook/folderMap.xml","utf-8")
success = htFolderMap.AddFromXmlSb(sbMap)

//  Get the IDs for the source and destination folders.
Dim srcFolderId As String
srcFolderId = htFolderMap.LookupStr("/Inbox/abc/subFolderA")
If (htFolderMap.LastMethodSuccess <> True) Then
    System.DebugLog("Folder ID not found")
    Return
End If

Dim dstFolderId As String
dstFolderId = htFolderMap.LookupStr("/Inbox/xyz")
If (htFolderMap.LastMethodSuccess <> True) Then
    System.DebugLog("Destination folder ID not found")
    Return
End If

//  Create a JSON request body with this content:
//  
//  		{
//  		  "DestinationId": "destinationId-value"
//  		}

Dim jsonRequestBody As New Chilkat.JsonObject
success = jsonRequestBody.UpdateString("DestinationId",dstFolderId)

success = http.SetUrlVar("src_folder_id",srcFolderId)

//  Copy the source folder to the new location
Dim resp As New Chilkat.HttpResponse
success = http.HttpJson("POST","https://graph.microsoft.com/v1.0/me/mailFolders/{$src_folder_id}/copy",jsonRequestBody,"application/json",resp)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

//  A 201 response indicates success.
If (resp.StatusCode = 201) Then
    System.DebugLog("Folder copied.")
Else
    System.DebugLog("Response status code = " + Str(resp.StatusCode))
    System.DebugLog("Error: Folder not copied.")
End If

//  Show the response in both cases..
Dim jsonResponse As New Chilkat.JsonObject
jsonResponse.EmitCompact = False
success = jsonResponse.Load(resp.BodyStr)
System.DebugLog(jsonResponse.Emit())

//  A sample successful JSON response looks like this:

//  	{
//  	  "@odata.context": "https://graph.microsoft.com/v1.0/$metadata#mailFolder",
//  	  "@odata.type": "#microsoft.graph.mailFolder",
//  	  "id": "AQMkADAwATM0MDAAMS1iNTcwLWI2NTEtMDACLTAwCgAuAAADsVyfxjDU406Ic4X7ill8xAEA5_vF7TKKdE6bGCRqXyl2PQAAAM6JqMAAAAA=",
//  	  "displayName": "subFolderA",
//  	  "parentFolderId": "AQMkADAwATM0MDAAMS1iNTcwLWI2NTEtMDACLTAwCgAuAAADsVyfxjDU406Ic4X7ill8xAEA5_vF7TKKdE6bGCRqXyl2PQAAAL8huwEAAAA=",
//  	  "childFolderCount": 1,
//  	  "unreadItemCount": 0,
//  	  "totalItemCount": 0
//  	}