Xojo Plugin

Duplicate openssl dgst -sha256 -sign private.pem -out sha256.sig in.dat

See more OpenSSL Examples

Demonstrates how to duplicate this OpenSSL command:

openssl dgst -sha256 -sign private.pem -out sha256.sig in.dat

The in.dat file can contain text or binary data of any type. The OpenSSL command does the following:

1. Creates a SHA256 digest of the contents of the input file
2. Signs the SHA256 digest using the private key.

Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim pkey As New Chilkat.PrivateKey

// Load the private key from an PEM file:
success = pkey.LoadPemFile("private.pem")
If (success = False) Then
    System.DebugLog(pkey.LastErrorText)
    Return
End If

Dim rsa As New Chilkat.Rsa

// Import the private key into the RSA component:
success = rsa.UsePrivateKey(pkey)
If (success = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// OpenSSL uses big-endian.
rsa.LittleEndian = False

// Load the file to be signed.
Dim bdFileData As New Chilkat.BinData
success = bdFileData.LoadFile("in.dat")

Dim bdSig As New Chilkat.BinData
success = rsa.SignBd(bdFileData,"sha256",bdSig)
If (success = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// Save the binary signature to a file.
success = bdSig.WriteFile("signature.sig")
If (success <> True) Then
    System.DebugLog("Failed to write signature.sig.")
    Return
End If

System.DebugLog("Success.")