Xojo Plugin Requires Chilkat v11.0.0+

Validate Certificate using OCSP Protocol

See more Certificates Examples

Demonstrates how to validate a certificate (check the revoked status) using the OCSP protocol. Xojo Plugin

Dim success As Boolean
success = False

//  This requires the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  This example will check the revoked status of a certificate loaded from a file.
Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("qa_data/certs/google.crt")
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

//  Get the cert's OCSP URL.
Dim ocspUrl As String
ocspUrl = cert.OcspUrl

//  Build the JSON that will be the OCSP request.

//  Possible hash algorithms are sha1, sha256, sha384, sha512.  
Dim hashAlg As String
hashAlg = "sha256"
Dim prng As New Chilkat.Prng
Dim json As New Chilkat.JsonObject
json.EmitCompact = False
//  Read more about OCSP nonce lengths
success = json.UpdateString("extensions.ocspNonce",prng.GenRandom(16,"base64"))
json.I = 0
success = json.UpdateString("request[i].cert.hashAlg",hashAlg)
success = json.UpdateString("request[i].cert.issuerNameHash",cert.HashOf("IssuerDN",hashAlg,"base64"))
success = json.UpdateString("request[i].cert.issuerKeyHash",cert.HashOf("IssuerPublicKey",hashAlg,"base64"))
success = json.UpdateString("request[i].cert.serialNumber",cert.SerialNumber)

System.DebugLog(json.Emit())

//  Our OCSP request looks something like this:
//  {
//    "extensions": {
//      "ocspNonce": "qZDfbpO+nUxRzz6c/SPjE5QCAsPfpkQlRDxTnGl0gnxt7iXO"
//    },
//    "request": [
//      {
//        "cert": {
//          "hashAlg": "sha1",
//          "issuerNameHash": "9u2wY2IygZo19o11oJ0CShGqbK0=",
//          "issuerKeyHash": "d8K4UJpndnaxLcKG0IOgfqZ+uks=",
//          "serialNumber": "6175535D87BF94B6"
//        }
//      }
//    ]
//  }

Dim ocspRequest As New Chilkat.BinData
Dim http As New Chilkat.Http

//  Convert our JSON to a binary (ASN.1) OCSP request
success = http.CreateOcspRequest(json,ocspRequest)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

//  Send the OCSP request to the OCSP server
Dim resp As New Chilkat.HttpResponse
success = http.HttpBd("POST",ocspUrl,ocspRequest,"application/ocsp-request",resp)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

//  Get the binary (ASN.1) OCSP reply
Dim ocspReply As New Chilkat.BinData
success = resp.GetBodyBd(ocspReply)

//  Convert the binary reply to JSON.
//  Also returns the overall OCSP response status.
Dim jsonReply As New Chilkat.JsonObject
Dim ocspStatus As Int32
ocspStatus = http.ParseOcspReply(ocspReply,jsonReply)

//  The ocspStatus can have one of these values:
//  -1:  The ARG1 does not contain a valid OCSP reply.
//  0:  Successful - Response has valid confirmations..
//  1: Malformed request - Illegal confirmation request.
//  2: Internal error - Internal error in issuer.
//  3: Try later -  Try again later.
//  4: Not used - This value is never returned.
//  5: Sig required - Must sign the request.
//  6: Unauthorized - Request unauthorized.

If (ocspStatus < 0) Then
    System.DebugLog("Invalid OCSP reply.")
    Return
End If

System.DebugLog("Overall OCSP Response Status: " + Str(ocspStatus))

//  Let's examine the OCSP response (in JSON).
jsonReply.EmitCompact = False
System.DebugLog(jsonReply.Emit())

//  The JSON reply looks like this:
//  (Use the online tool at https://tools.chilkat.io/jsonParse.cshtml
//  to generate JSON parsing code.)

//  {
//    "responseStatus": 0,
//    "responseTypeOid": "1.3.6.1.5.5.7.48.1.1",
//    "responseTypeName": "ocspBasic",
//    "response": {
//      "responderIdChoice": "KeyHash",
//      "responderKeyHash": "d8K4UJpndnaxLcKG0IOgfqZ+uks=",
//      "dateTime": "20180803193937Z",
//      "cert": [
//        {
//          "hashOid": "1.3.14.3.2.26",
//          "hashAlg": "SHA-1",
//          "issuerNameHash": "9u2wY2IygZo19o11oJ0CShGqbK0=",
//          "issuerKeyHash": "d8K4UJpndnaxLcKG0IOgfqZ+uks=",
//          "serialNumber": "6175535D87BF94B6",
//          "status": 0,
//          "thisUpdate": "20180803193937Z",
//          "nextUpdate": "20180810193937Z"
//        }
//      ]
//    }
//  }
//  

//  The certificate status:
Dim certStatus As Int32
certStatus = -1
If (jsonReply.HasMember("response.cert[0].status") = True) Then
    certStatus = jsonReply.IntOf("response.cert[0].status")
End If

//  Possible certStatus values are:
//  -1: No status returned.
//  0: Good
//  1: Revoked
//  2: Unknown.
System.DebugLog("Certificate Status: " + Str(certStatus))