Xojo Plugin

OAuth2 using a SOCKS Proxy (for a Desktop Application)

See more OAuth2 Examples

Explains how to use a SOCKS proxy to send OAuth2 communications for a desktop application, using Microsoft Graph as an example. This method applies to all OAuth2 applications. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// To use a SOCKS proxy with OAuth2, create a Chilkat socket object and specify the details for the
// SOCKS proxy server (SOCKS4 or SOCKS5).
Dim socket As New Chilkat.Socket
// Use your SOCKS proxy server domain or IP address.
socket.SocksHostname = "mysocksproxyserver.com"
// Change this to the listening port of your SOCKS proxy server (if necessary)
socket.SocksPort = 1080
socket.SocksUsername = "myProxyLogin"
socket.SocksPassword = "myProxyPassword"
// Set the SOCKS version to 4 or 5 based on the version
// of the SOCKS proxy server:
socket.SocksVersion = 5
// Note: SOCKS4 servers only support usernames without passwords.
// SOCKS5 servers support full login/password authentication.

Dim oauth2 As New Chilkat.OAuth2

// We don't need to connect the socket beforehand.
// Just tell oauth2 to use the socket which has the SOCKS proxy properties.
success = oauth2.UseConnection(socket)

// This should be the port in the localhost callback URL for your app.  
// The callback URL would look like "http://localhost:3017/" if the port number is 3017.
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
oauth2.TokenEndpoint = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

// Replace these with actual values.
oauth2.ClientId = "MICROSOFT-GRAPH-CLIENT-ID"
// This is your app password:
oauth2.ClientSecret = "MICROSOFT-GRAPH-CLIENT-SECRET"

oauth2.CodeChallenge = False
// Provide a SPACE separated list of scopes.
// See https://developer.microsoft.com/en-us/graph/docs/authorization/permission_scopes 

// Important: To get a refresh token in the final response, you have to ask for "offline_access" scope
oauth2.Scope = "openid profile offline_access user.readwrite mail.readwrite mail.send files.readwrite"

// Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> True) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

System.DebugLog("url = " + url)

// Launch the default browser on the system and navigate to the url.
// The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = False) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

// Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Int32
numMsWaited = 0
While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Wend

// If the browser does not respond within the specified time, AuthFlowState will be:
// 
// 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
// 2: Waiting for Final Response - The thread is awaiting the final access token response.
// In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    System.DebugLog("No response from the browser!")
    Return
End If

// Check AuthFlowState to determine if authorization was granted, denied, or failed:
// 
// 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
// 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
// 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    System.DebugLog("OAuth2 failed to complete.")
    System.DebugLog(oauth2.FailureInfo)
    Return
End If

If (oauth2.AuthFlowState = 4) Then
    System.DebugLog("OAuth2 authorization was denied.")
    System.DebugLog(oauth2.AccessTokenResponse)
    Return
End If

If (oauth2.AuthFlowState <> 3) Then
    System.DebugLog("Unexpected AuthFlowState:" + Str(oauth2.AuthFlowState))
    Return
End If

System.DebugLog("OAuth2 authorization granted!")
System.DebugLog("Access Token = " + oauth2.AccessToken)

// Get the full JSON response:
Dim json As New Chilkat.JsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = False

// The JSON response looks like this:

// {
//   "token_type": "Bearer",
//   "scope": "User.Read Mail.ReadWrite Mail.Send",
//   "expires_in": 3600,
//   "ext_expires_in": 0,
//   "access_token": "EwBAA8l6B...",
//   "refresh_token": "MCRMdbe...",
//   "id_token": "eyJ0eXA..."
// }

// If an "expires_on" member does not exist, then add the JSON member by
// getting the current system date/time and adding the "expires_in" seconds.
// This way we'll know when the token expires.
If (json.HasMember("expires_on") <> True) Then
    Dim dtExpire As New Chilkat.CkDateTime
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(json.IntOf("expires_in"))
    success = json.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(False))
End If

System.DebugLog(json.Emit())

// Save the JSON to a file for future requests.
Dim fac As New Chilkat.FileAccess
success = fac.WriteEntireTextFile("qa_data/tokens/microsoftGraph.json",json.Emit(),"utf-8",False)