(Xojo Plugin) MyInvois Malaysia Submit Document

See more Malaysia MyInvois Examples

Demonstrates how to submit a document to MyInvois.

For more information, see https://sdk.myinvois.hasil.gov.my/einvoicingapi/02-submit-documents/

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http
Dim success As Boolean

// The following JSON is sent in the request body.

// {
//   "documents": [
//     {
//       "format": "XML",
//       "documentHash": "<SHA256_hash_of_document>",
//       "codeNumber": "INV12345",
//       "document": "<Document_encoded_in_Base64>"
//     }
//   ]
// }

// Load the document to be sent.
Dim sbXmlDoc As New Chilkat.StringBuilder
success = sbXmlDoc.LoadFile("c:/invoices/invoice1.xml","utf-8")

// The MyInvois online documentation neglects to tell us the encoding of the documentHash.
// Should it be base64?  Or hex?  We can only guess.  MyInvois provides no samples,
// and omits these crucial details which are needed for actual implementation.
// 
// *** Note: It was confirmed that "hex" is the encoding that is needed.
Dim sha256 As String
sha256 = sbXmlDoc.GetHash("sha256","hex","utf-8")

Dim sbEncoded As New Chilkat.StringBuilder
success = sbEncoded.AppendSb(sbXmlDoc)
success = sbEncoded.Encode("base64","utf-8")

Dim json As New Chilkat.JsonObject
success = json.UpdateString("documents[0].format","XML")
success = json.UpdateString("documents[0].documentHash",sha256)
success = json.UpdateString("documents[0].codeNumber","INV12345")
success = json.UpdateSb("documents[0].document",sbEncoded)

// Adds the "Authorization: Bearer <access_token>" header.
http.AuthToken = "<access_token>"

Dim resp As Chilkat.HttpResponse
resp = http.PostJson3("https://preprod-api.myinvois.hasil.gov.my/api/v1.0/documentsubmissions","application/json",json)
If (http.LastMethodSuccess = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

System.DebugLog("response status code = " + Str(resp.StatusCode))
System.DebugLog(resp.BodyStr)