(Xojo Plugin) Another SOAP with MTOM XOP Attachment Example

See more HTTP Examples

Demonstrates another multipart/related MTOM SOAP request that adds additional headers in each MIME sub-part, and also specifies Content-Transfer-Encoding in the sub-parts.

Note: This example requires Chilkat v9.5.0.92 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Note: This example requires Chilkat v9.5.0.92 or greater.

// This example sends a request such as the following:

// POST /FseInsServicesWeb/services/fseComunicazioneMetadati HTTP/1.1
// Connection: Keep-Alive
// Content-Length: 50649
// Content-Type: multipart/related; type="application/xop+xml"; start="<rootpart@soapui.org>"; start-info="text/xml"; boundary="----=_Part_0_355796458.1662133302632"
// Accept-Encoding: gzip,deflate
// Authorization: Basic xxxxx
// Host: ...
// SOAPAction: "http://comunicazionemetadati.wsdl.fse.ini.finanze.it/ComunicazioneMetadati"
// MIME-Version: 1.0
// 
// ------=_Part_0_355796458.1662133302632
// Content-Type: application/xop+xml; charset=UTF-8; type="text/xml"
// Content-Transfer-Encoding: 8bit
// Content-ID: <rootpart@soapui.org>
// 
// <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:com="http://comunicazionemetadatirichiesta.xsd.fse.ini.finanze.it" xmlns:tip="http://tipodaticomunicazionemetadati.xsd.fse.ini.finanze.it">
// <soapenv:Header/>
// ...
// 
// ------=_Part_0_355796458.1662133302632
// Content-Type: text/xml; charset=Cp1252
// Content-Transfer-Encoding: quoted-printable
// Content-ID: <CDA2LAB_190_signed.xml>
// Content-Disposition: attachment; name="CDA2LAB_190_signed.xml"
// 
// <!-- INSERIRE IL RIFERIMENTO AL FOGLIO DI STILE DI AGID OPPURE INSERIRNE UN=
// ...
// 
// ------=_Part_0_355796458.1662133302632--

Dim http As New Chilkat.Http
Dim req As New Chilkat.HttpRequest

req.HttpVerb = "POST"
req.Path = "/FseInsServicesWeb/services/fseComunicazioneMetadati"

// Chilkat will automatically generate and add a boundary string.
req.ContentType = "multipart/related; type=""application/xop+xml""; start=""<rootpart@soapui.org>""; start-info=""text/xml"""
req.AddHeader "SOAPAction","some-SOAP-action"

req.AddHeader "Connection","Keep-Alive"
req.AddHeader "Accept-Encoding","gzip,deflate"
req.AddHeader "MIME-Version","1.0"

// Chilkat will automatically add the Content-Length and Host headers.

// The "Authorization: Basic ..."  header is added by setting the Login and Password and specifying Basic authentication:
http.Login = "..."
http.Password = "..."
http.BasicAuth = True

// Add the 1st multipart/related sub-part, which is the SOAP envelope.
Dim xmlBody As String
xmlBody = "<soapenv:Envelope ...."
Dim success As Boolean
success = req.AddStringForUpload2("","",xmlBody,"utf-8","application/xop+xml; type=""text/xml""; charset=utf-8")

// Additional headers for the 1st sub-part
success = req.AddSubHeader(0,"Content-ID","<rootpart@soapui.org>")
success = req.AddSubHeader(0,"Content-Transfer-Encoding","8bit")
success = req.AddSubHeader(0,"Content-Disposition","")

// Add the 2nd multipart/related sub-part, which is the signed XML
Dim xmlBody2 As String
xmlBody2 = "<!-- INSERIRE IL RIFERIMENT ...."
success = req.AddStringForUpload2("CDA2LAB_190_signed.xml","",xmlBody2,"Cp1252","text/xml; charset=Cp1252")

// Additional headers for the 2nd sub-part.
success = req.AddSubHeader(1,"Content-ID","<CDA2LAB_190_signed.xml>")
success = req.AddSubHeader(1,"Content-Transfer-Encoding","quoted-printable")
success = req.AddSubHeader(1,"Content-Disposition","attachment; name=""CDA2LAB_190_signed.xml""")

http.FollowRedirects = True

Dim useTls As Boolean
useTls = True
Dim resp As Chilkat.HttpResponse
resp = http.SynchronousRequest("fseservicetest.sanita.finanze.it",443,useTls,req)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

Dim xmlResponse As New Chilkat.Xml
success = xmlResponse.LoadXml(resp.BodyStr)
System.DebugLog(xmlResponse.GetXml())