(Xojo Plugin) Create Binary MIME

Demonstrates how to create and save a multipart/mixed MIME document where the parts (a JPG and a PDF) are NOT base64 encoded, but are instead binary.

Note: This example requires Chilkat v9.5.0.62 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim mime As New Chilkat.Mime
Dim success As Boolean

success = mime.SetBodyFromPlainText("This is the plain text body.")
success = mime.ConvertToMultipartMixed()
success = mime.AppendPartFromFile("qa_data/jpg/penguins.jpg")
success = mime.AppendPartFromFile("qa_data/pdf/fishing.pdf")

// At this point, when saved, the MIME bodies will be base64 encoded.
success = mime.SaveMime("qa_output/sample.txt")

// We now have the following MIME where everything is base64 encoded:
// The code that follows shows how to eliminate the base64 to make this binary MIME.

// 	Content-Type: multipart/mixed; boundary="------------000207060703080505060404"
// 
// 	--------------000207060703080505060404
// 	Content-Type: text/plain
// 	Content-Transfer-Encoding: 7bit
// 
// 	This is the plain text body.
// 	--------------000207060703080505060404
// 	Content-Disposition: attachment; filename="penguins.jpg"
// 	Content-Type: image/jpeg; name="penguins.jpg"
// 	Content-Transfer-Encoding: base64
// 
// 	/9j/4AAQSkZJRgABAgEAYABgAAD/7gAOQWRvYmUAZAAAAAAB/+ESCEV4aWYAAE1NACoAAAAIAAcB
// 	MgACAAAAFAAAAGIBOwACAAAABwAAAHZHRgADAAAAAQAEAABHSQADAAAAAQA/AACcnQABAAAADgAA
// 	...
// 	800a1MlLipJHlyU9en7sqVPkBK+gBj+o+1E91Ld7iJk0pJDO5PmDk4FOGOHy6S3JW120W1uCJ5M0
// 	PBa54edOFAc8ePX/2Q==
// 
// 	--------------000207060703080505060404
// 	Content-Disposition: attachment; filename="fishing.pdf"
// 	Content-Type: application/pdf; name="fishing.pdf"
// 	Content-Transfer-Encoding: base64
// 
// 	JVBERi0xLjMKJcfsj6IKNSAwIG9iago8PC9MZW5ndGggNiAwIFIvRmlsdGVyIC9GbGF0ZURlY29k
// 	ZT4+CnN0cmVhbQp4nM1c288cNxVX09A0myq35tom7bSl8E1hp76P/YpASIiXlEg8tDwVKEJfilIe
// 	...
// 	MDRGMT48OTlENkRFQzExQjkzNjA0Mjc1RUFCNzIyMjI4RjA0RjE+XQo+PgpzdGFydHhyZWYKMjk0
// 	MzY5CiUlRU9GCg==
// 
// 	--------------000207060703080505060404--
// 

// To make it binary MIME (getting rid of the base64), set the Encoding property to "binary"
// for the JPG and PDF parts.
Dim jpgPart As Chilkat.Mime
jpgPart = mime.GetPart(1)
jpgPart.Encoding = "binary"

Dim pdfPart As Chilkat.Mime
pdfPart = mime.GetPart(2)
pdfPart.Encoding = "binary"

// Now save it.  If you try to view this MIME in a text editor,
// the JPG and PDF parts will be garbled and unintelligible. That's because
// the bytes do not represent characters.
success = mime.SaveMime("qa_output/sampleBinary.mim")

// The MIME now contains this:

// 	Content-Type: multipart/mixed; boundary="------------000207060703080505060404"
// 
// 	--------------000207060703080505060404
// 	Content-Type: text/plain
// 	Content-Transfer-Encoding: 7bit
// 
// 	This is the plain text body.
// 	--------------000207060703080505060404
// 	Content-Disposition: attachment; filename="penguins.jpg"
// 	Content-Type: image/jpeg; name="penguins.jpg"
// 	Content-Transfer-Encoding: binary
// 
// 	<Binary Data Here>
// 
// 	--------------000207060703080505060404
// 	Content-Disposition: attachment; filename="fishing.pdf"
// 	Content-Type: application/pdf; name="fishing.pdf"
// 	Content-Transfer-Encoding: binary
// 
// 	<Binary Data Here>
// 
// 	--------------000207060703080505060404--
// 

// Can we load this binary MIME into an Email object?
Dim binData As New Chilkat.BinData
// Write the binary MIME into binData;
success = mime.GetMimeBd(binData)

Dim email As New Chilkat.Email
// Load the email from the binData.
success = email.SetFromMimeBd(binData)

// Note: Many email clients may not be able to correctly process emails
// using the binary encoding.  Thunderbird has trouble.  Windows Live Mail
// worked OK.
email.Subject = "Binary MIME Email"
email.From = "admin@chilkatsoft.com"
success = email.AddTo("Chilkat","support@chilkatsoft.com")
success = email.SaveEml("qa_output/binaryEmail.eml")

// Chilkat does not recommend trying to use binary MIME for email.
// Binary MIME is typically used in HTTP for uploads and downloads.
// 

// Also, binary MIME is not representable in a string.  
// If we try to get the MIME as a string, then it must be encoded
// using base64.

// Chilkat automatically changes binary encodings to base64
// when there's an attempt to get the MIME as a string.
Dim sb As New Chilkat.StringBuilder
success = email.GetMimeSb(sb)
success = sb.WriteFile("qa_output/email_fromSb.eml","utf-8",False)

// Likewise, if we try to get the MIME as a string from the Mime object, 
// it cannot contain non-character data in a binary encoding.  The binary
// bytes MUST be in base64.  The act of trying to retrieve the MIME in string
// format will force Chilkat to convert binary encodings (for non-text parts)
// to base64.
success = mime.GetMimeSb(sb)
success = sb.WriteFile("qa_output/mime_fromSb.eml","utf-8",False)

// However, the above use of base64 is just for the purpose of making the MIME
// string friendly.  If we save the MIME to a file, it's still binary:
success = mime.SaveMime("qa_output/mime_binary.mime")