(Xojo Plugin) MIME Body vs. Sub-Parts
Explains the difference between sub-parts and body.
MIME documents (i.e. messages) can have a nested structure. The simplest MIME message contains a header followed by content (possibly encoded). The header is delimited from the content by two consecutive CRLF's.
A MIME message may be multipart. If so, then the Content-Type header field indicates "multipart" and the content the follows the header is itself a MIME message, which may also be multipart, etc. You can see how MIME messages effectively have a tree structure. The non-leaf nodes have Content-Types that are "multipart/" and the leaf nodes have non-multipart Content-Types.
The Chilkat MIME component/library uses two terms that need to be understood in order to effectively use the API. These are "body" and "sub-part". A multipart node has 1 or more sub-parts, but its body is empty. A leaf node (i.e. non-multipart node) has no sub-parts, but the body is (usually) non-empty.
This example creates a multipart MIME message and shows the results of getting the sub-parts and body of each node.
// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.
Dim mime As New Chilkat.Mime
// Create a multipart/mixed MIME message with two sub-parts.
// We'll use the Base64 encoding for the 2nd sub-part.
Dim part1 As New Chilkat.Mime
Dim success As Boolean
success = part1.SetBodyFromPlainText("This is part 1")
Dim part2 As New Chilkat.Mime
success = part2.SetBodyFromPlainText("This is part 2")
part2.Encoding = "base64"
success = mime.NewMultipartMixed()
mime.UseMmDescription = False
success = mime.AppendPart(part1)
success = mime.AppendPart(part2)
// Show the MIME message:
System.DebugLog(mime.GetMime())
// Here's the MIME:
// Content-Type: multipart/mixed;
// boundary="------------040605030407000302060008"
//
// --------------040605030407000302060008
// Content-Type: text/plain;
// charset="us-ascii"
// Content-Transfer-Encoding: 7bit
//
// This is part 1
// --------------040605030407000302060008
// Content-Type: text/plain;
// charset="us-ascii"
// Content-Transfer-Encoding: base64
//
// VGhpcyBpcyBwYXJ0IDI=
//
// --------------040605030407000302060008--
// If we examine the root node of the MIME message,
// we see that it has 2 sub-parts and the body is empty (as expected)
Dim n As Int32
n = mime.NumParts
System.DebugLog("Num Parts = " + Str(n))
System.DebugLog("Body = " + mime.GetBodyDecoded())
// The GetEntireBody retrieves the entire content after
// the header. (Perhaps GetEntireBody should've been named
// GetEntireContent to make it less confusing...)
System.DebugLog("---- EntireBody:")
System.DebugLog(mime.GetEntireBody())
System.DebugLog("********")
// Now examine the 2nd sub-part. It has a body encoded
// using base64. Get the contents of the body in both
// decoded and encoded forms:
Dim part As Chilkat.Mime
// index 0 is the 1st part, index 1 is the 2nd part.
part = mime.GetPart(1)
System.DebugLog("Decoded Body:")
System.DebugLog(part.GetBodyDecoded())
System.DebugLog("Encoded Body:")
System.DebugLog(part.GetBodyEncoded())
|
