(Xojo Plugin) MercadoLibre Refresh OAuth2 Access Token

Demonstrates how to refresh a MercadoLibre OAuth2 access token. The refresh does not require user interaction via a web browser. If an access token expires (typically with a 401 response code), a new access token can be automatically obtained by using the code in this example.

For more information, see https://developers.mercadolibre.com.ar/es_ar/autenticacion-y-autorizacion#Refresh-token

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// It is assumed we previously obtained an OAuth2 access token.
// This example loads the JSON access token file 
// saved by this example: Get MercadoLibre OAuth2 Access Token

Dim jsonToken As New Chilkat.JsonObject
Dim success As Boolean
success = jsonToken.LoadFile("qa_data/tokens/mercadolibre.json")
If (success <> True) Then
    System.DebugLog("Failed to load mercadolibre.json")
    Return
End If

// The access token JSON looks like this:

// {
//   "access_token": "APP_USR-8133606632685744-060115-93e1fd8b5e767c51c238df347bd0b288-577628017",
//   "token_type": "bearer",
//   "expires_in": 21600,
//   "scope": "offline_access read write",
//   "user_id": 577625107,
//   "refresh_token": "TG-5ad522a286f1200006ac4ed1-577625007"
// }

Dim oauth2 As New Chilkat.OAuth2

oauth2.TokenEndpoint = "https://api.mercadolibre.com/oauth/token"

// Replace these with actual values.
oauth2.ClientId = "MY_MERCADOLIBRE_APP_ID"
oauth2.ClientSecret = "MY_MERCADOLIBRE_APP_SECRET"

// Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

// Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> True) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

System.DebugLog("New access token: " + oauth2.AccessToken)
System.DebugLog("New refresh token: " + oauth2.RefreshToken)

// Update the JSON with the new tokens.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)
success = jsonToken.UpdateString("refresh_token",oauth2.RefreshToken)

// Save the new JSON access token response to a file.
Dim sbJson As New Chilkat.StringBuilder
jsonToken.EmitCompact = False
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/mercadolibre.json","utf-8",False)

System.DebugLog("OAuth2 authorization granted!")
System.DebugLog("New Access Token = " + oauth2.AccessToken)