(Xojo Plugin) Create JWT Using HS256, HS384, or HS512

Demonstrates how to create a JWT using HS256, HS384, or HS512. (HS256 is JWT's acronym for HMAC-SHA256.) When HMAC is used, the secret is a shared secret (i.e. password) that both client and server know beforehand.

This example also demonstrates how to include time constraints:

• nbf: Not Before Time
• exp: Expiration Time
• iat: Issue At Time

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Demonstrates how to create an HMAC JWT using a shared secret (password).

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim jwt As New Chilkat.Jwt

// Build the JOSE header
Dim jose As New Chilkat.JsonObject
// Use HS256.  Pass the string "HS384" or "HS512" to use a different algorithm.
Dim success As Boolean
success = jose.AppendString("alg","HS256")
success = jose.AppendString("typ","JWT")

// Now build the JWT claims (also known as the payload)
Dim claims As New Chilkat.JsonObject
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

// Set the timestamp of when the JWT was created to now.
Dim curDateTime As Int32
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

// Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

// Set the timestamp defining an expiration time (end time) for the token
// to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

// Produce the smallest possible JWT:
jwt.AutoCompact = True

Dim strJwt As String
strJwt = jwt.CreateJwt(jose.Emit(),claims.Emit(),"secret")

System.DebugLog(strJwt)