(Xojo Plugin) JWE using PBES2 Key Wrapping

Demonstrates how to create and decrypt a JWE that using PBES2 key wrapping.

This example demonstrates PBES2 with HMAC SHA-256 and A128KW wrapping. It is also possible to do the following by simply changing the "alg" parameter:

• PBES2 with HMAC SHA-384 and A192KW wrapping
• PBES2 with HMAC SHA-512 and A256KW wrapping

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Note: This example requires Chilkat v9.5.0.66 or greater.

Dim success As Boolean
Dim plaintext As String
plaintext = "Live long and prosper."

Dim jwe As New Chilkat.Jwe

// First build the JWE Protected Header..
Dim jweProtHdr As New Chilkat.JsonObject
success = jweProtHdr.AppendString("alg","PBES2-HS256+A128KW")
success = jweProtHdr.AppendString("enc","A128GCM")

// PBES2 requires two additional parameters:
// 1) A random salt parameter ("p2s") containing 8 or more bytes in base64url format.
// 2) An iteration count parameter ("p2c").  A minimum count of 1000 is recommended.
//    The iteration count is intended to make the PBES2 computation more expensive (time consuming)
//    to prevent brute-force attacks.
Dim prng As New Chilkat.Prng
success = jweProtHdr.AppendString("p2s",prng.GenRandom(16,"base64url"))
success = jweProtHdr.AppendString("p2c","1000")

System.DebugLog("JWE Protected Header: " + jweProtHdr.Emit())
System.DebugLog("--")

// Don't forget to actually provide the protected header to the JWE object:
success = jwe.SetProtectedHeader(jweProtHdr)

// Set the PBES2 password
Dim recipientIndex As Int32
recipientIndex = 0
success = jwe.SetPassword(recipientIndex,"top secret")

// Encrypt and return the JWE:
Dim strJwe As String
strJwe = jwe.Encrypt(plaintext,"utf-8")
If (jwe.LastMethodSuccess <> True) Then
    System.DebugLog(jwe.LastErrorText)
    Return
End If

// Show the JWE we just created:
System.DebugLog(strJwe)

// Decrypt the JWE.
Dim jwe2 As New Chilkat.Jwe
success = jwe2.LoadJwe(strJwe)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

// Set the PBES2 password
success = jwe2.SetPassword(recipientIndex,"top secret")

// Decrypt.
Dim originalPlaintext As String
originalPlaintext = jwe2.Decrypt(0,"utf-8")
If (jwe2.LastMethodSuccess <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

System.DebugLog("original text: ")
System.DebugLog(originalPlaintext)

// Sample output:

// JWE Protected Header: {"alg":"PBES2-HS256+A128KW","enc":"A128GCM","p2s":"z39rTEfRy1T1Yn_D1mZRlg","p2c":"1000"}
// --
// eyJhbGciOiJQQkVTMi1IUzI1NitBMTI4S1ciLCJlbmMiOiJBMTI4R0NNIiwicDJzIjoiejM5clRFZlJ5MVQxWW5fRDFtWlJsZyIsInAyYyI6IjEwMDAifQ.koYt6PrFmYwcwdcT7ZcvXHA1d-Xez5h4.luGlbvEnZp-7IsBOj42Yhw.YMTcfLf8Qe4zazozGV2OAu3cUdQ8Kg.rWub47ESWkc6IqZJTvSTmg
// original text: 
// Live long and prosper.