Xojo Plugin

JWE with Binary Data

See more JSON Web Encryption (JWE) Examples

Demonstrates how to create a JWE that contains a binary payload (such as a JPG image).

Note: This example requires Chilkat v9.5.0.66 or greater.

Xojo Plugin

Dim success As Boolean
success = False

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Note: This example requires Chilkat v9.5.0.66 or greater.

// Load a JPG file that will be the JWE payload.
Dim jpgBytes As New Chilkat.BinData
success = jpgBytes.LoadFile("qa_data/jpg/starfish.jpg")
// Make sure your app checks the success/failure of the call to LoadFile..
System.DebugLog("Original JPG size = " + Str(jpgBytes.NumBytes))

Dim jwe As New Chilkat.Jwe

Dim jweProtHdr As New Chilkat.JsonObject
success = jweProtHdr.AppendString("alg","A128KW")
success = jweProtHdr.AppendString("enc","A128CBC-HS256")
success = jwe.SetProtectedHeader(jweProtHdr)

Dim aesWrappingKey As String
aesWrappingKey = "GawgguFyGrWKav7AX4VKUg"
success = jwe.SetWrappingKey(0,aesWrappingKey,"base64url")

// Encrypt and return the JWE in sbJwe:
Dim sbJwe As New Chilkat.StringBuilder
success = jwe.EncryptBd(jpgBytes,sbJwe)
If (success <> True) Then
    System.DebugLog(jwe.LastErrorText)
    Return
End If

// Show the JWE:
System.DebugLog(sbJwe.GetAsString())
System.DebugLog("size of JWE: " + Str(sbJwe.Length))

// ---------------------------------------------------------
// Decrypt to get the original JPG file..

Dim jwe2 As New Chilkat.Jwe
success = jwe2.LoadJweSb(sbJwe)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

// Set the AES wrap key.
success = jwe2.SetWrappingKey(0,aesWrappingKey,"base64url")

// Decrypt.
Dim jpgOriginal As New Chilkat.BinData
success = jwe2.DecryptBd(0,jpgOriginal)
If (success <> True) Then
    System.DebugLog(jwe2.LastErrorText)
    Return
End If

System.DebugLog("Decrypted JPG size = " + Str(jpgOriginal.NumBytes))

// Save the decrypted JPG to a file.
success = jpgOriginal.WriteFile("qa_output/jwe_decrypted_starfish.jpg")

System.DebugLog("success = " + Str(success))

// The output of this program, when tested, was:
// Original JPG size = 6229
// eyJhbGciOiJBMTI4S1ciLCJlbmMiOiJBMTI4Q0JDLUhTMjU2In0.9YFz_wteV ... 7Et3hKhpxnKEXw
// size of JWE: 8473
// Decrypted JPG size = 6229
// success = True