Xojo Plugin

JSON Paths

See more JSON Examples

Demonstrates using "Chilkat JSON Paths" to access parts of a JSON document, or to iterate over parts.

This example uses the following JSON document:

{
    "nestedArray" : [
			[
				[1,2,3],
				[4,5,6],
				[7,8,9,10]
			],
			[
				[11,12,13],
				[14,15,16],
				[17,18,19,20]
			],
			[
				[21,22,23],
				[24,25,26],
				[27,28,29,30],
				[31,32,33,34,35,36]
			]
		],

	"nestedObject" : {
		"aaa" : {
			"bb1" : {
				"cc1" : "c1Value",
				"cc2" : "c2Value",
				"cc3" : "c3Value"
			},
			"bb2" : {
				"dd1" : "d1Value",
				"dd2" : "d2Value",
				"dd3" : "d3Value"
			}
		}
	},

	"mixture" : {
		"arrayA" : [  
			{ "fruit": "apple", "animal": "horse", "job": "fireman", "colors": ["red","blue","green"] },
			{ "fruit": "pear", "animal": "plankton", "job": "waiter", "colors": ["yellow","orange","purple"] },
			{ "fruit": "kiwi", "animal": "echidna", "job": "astronaut", "colors": ["magenta","tan","pink"] }
			]
	},


        "name.with.dots" : { "grain" : "oats" }

	
}

Xojo Plugin

Dim success As Boolean
success = False

Dim json As New Chilkat.JsonObject
json.EmitCompact = False

// Assume the file contains the data as shown above..
success = json.LoadFile("qa_data/json/pathSample.json")
If (success = False) Then
    System.DebugLog(json.LastErrorText)
    Return
End If

// First, let's get the value of "cc1"
// The path to this value is: nestedObject.aaa.bb1.cc1
System.DebugLog(json.StringOf("nestedObject.aaa.bb1.cc1"))

// Now let's get number 18 from the nestedArray.
// It is located at nestedArray[1][2][1]
// (remember: Indexing is 0-based)
System.DebugLog("This should be 18: " + Str(json.IntOf("nestedArray[1][2][1]")))

// We can do the same thing in a more roundabout way using the 
// I, J, and K properties.  (The I,J,K properties will be convenient
// for iterating over arrays, as we'll see later.)
json.I = 1
json.J = 2
json.K = 1
System.DebugLog("This should be 18: " + Str(json.IntOf("nestedArray[i][j][k]")))

// Let's iterate over the array containing the numbers 17, 18, 19, 20.
// First, use the SizeOfArray method to get the array size:
Dim sz As Int32
sz = json.SizeOfArray("nestedArray[1][2]")
// The size should be 4.
System.DebugLog("size of array = " + Str(sz) + " (should equal 4)")

// Now iterate...
Dim i As Int32
For i = 0 To sz - 1
    json.I = i
    System.DebugLog(Str(json.IntOf("nestedArray[1][2][i]")))
Next

// Let's use a triple-nested loop to iterate over the nestedArray:
Dim j As Int32
Dim k As Int32

// szI should equal 1.
Dim szI As Int32
szI = json.SizeOfArray("nestedArray")
For i = 0 To szI - 1
    json.I = i

    Dim szJ As Int32
    szJ = json.SizeOfArray("nestedArray[i]")
    For j = 0 To szJ - 1
        json.J = j

        Dim szK As Int32
        szK = json.SizeOfArray("nestedArray[i][j]")
        For k = 0 To szK - 1
            json.K = k

            System.DebugLog(Str(json.IntOf("nestedArray[i][j][k]")))
        Next
    Next
Next

// Now let's examine how to navigate to JSON objects contained within JSON arrays.
// This line of code gets the value "kiwi" contained within "mixture"
System.DebugLog(json.StringOf("mixture.arrayA[2].fruit"))

// This line of code gets the color "yellow"
System.DebugLog(json.StringOf("mixture.arrayA[1].colors[0]"))

// Getting an object at a path:
// This gets the 2nd object in "arrayA"

Dim obj2 As New Chilkat.JsonObject
success = json.ObjectOf2("mixture.arrayA[1]",obj2)

// This object's "animal" should be "plankton"
System.DebugLog(obj2.StringOf("animal"))

// Note that paths are relative to the object, not the absolute root of the JSON document.
// Starting from obj2, "purple" is at "colors[2]"
System.DebugLog(obj2.StringOf("colors[2]"))

// Getting an array at a path:
// This gets the array containing the colors red, green, blue:

Dim arr1 As New Chilkat.JsonArray
success = json.ArrayOf2("mixture.arrayA[0].colors",arr1)

Dim szArr1 As Int32
szArr1 = arr1.Size
For i = 0 To szArr1 - 1
    System.DebugLog(Str(i) + ": " + arr1.StringAt(i))
Next

// The Chilkat JSON path uses ".", "[", and "]" chars for separators.  When a name
// contains one of these chars, use double-quotes in the path:
System.DebugLog(json.StringOf("""name.with.dots"".grain"))