(Xojo Plugin) Convert Java KeyStore to PEM

Loads a Java keystore file and saves the trusted certificate entries to a PEM file.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim jks As New Chilkat.JavaKeyStore

Dim jksPassword As String
jksPassword = "myJksPassword"

// Load the Java keystore from a file.  The JKS file password is used
// to verify the keyed digest that is found at the very end of the keystore.
// It verifies that the keystore has not been modified.
Dim success As Boolean
success = jks.LoadFile(jksPassword,"/someDir/keyStore.jks")
If (success <> True) Then
    System.DebugLog(jks.LastErrorText)
    Return
End If

// Open/create the output PEM file. 
// This example uses Chilkat's file access class for writing the output file.
// You may replace the file I/O lines of code with whatever is most convenient for you.
Dim fac As New Chilkat.FileAccess
success = fac.OpenForWrite("/pemFiles/caCerts.pem")
If (success <> True) Then
    System.DebugLog(fac.LastErrorText)
    Return
End If

Dim numCerts As Int32
numCerts = jks.NumTrustedCerts
Dim i As Int32

Dim cert As Chilkat.Cert
Dim pem As String

// Iterate over the trusted certs, get the PEM for each,
// and append it to the output file.
i = 0
While i < numCerts
    cert = jks.GetTrustedCert(i)

    // Get the certificate in PEM format.  
    pem = cert.ExportCertPem()

    // Append the PEM string to the open file.
    // The PEM contains only us-ascii chars..
    success = fac.AppendAnsi(pem)
    If (success <> True) Then
        System.DebugLog(fac.LastErrorText)

        Return
    End If

    i = i + 1
Wend

// Close the output file.
fac.FileClose 

System.DebugLog("Trusted certificates saved to PEM.")