(Xojo Plugin) Read iCloud Email Account using IMAP

Demonstrates how to set the IMAP settings for an iCloud email account and downloads the email from Inbox.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example assumes Chilkat Imap to have been previously unlocked.
// See Unlock Imap for sample code.

Dim imap As New Chilkat.Imap

// Connect to the iCloud IMAP Mail Server
imap.Ssl = True
imap.Port = 993
Dim success As Boolean
success = imap.Connect("imap.mail.me.com")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// The username is usually the name part of your iCloud email address 
// (for example, emilyparker, not emilyparker@icloud.com).
success = imap.Login("ICLOUD_USERNAME","ICLOUD_PASSWORD")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// Select an IMAP folder/mailbox
success = imap.SelectMailbox("Inbox")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// Once the folder/mailbox is selected, the NumMessages property
// will contain the number of emails in the mailbox.
// Loop from 1 to NumMessages to fetch each email by sequence number.

Dim email As Chilkat.Email
Dim i As Int32
Dim n As Int32
n = imap.NumMessages
Dim bUid As Boolean
bUid = False
For i = 1 To n

    // Download the email by sequence number.
    email = imap.FetchSingle(i,bUid)
    If (imap.LastMethodSuccess <> True) Then
        System.DebugLog(imap.LastErrorText)
        Return
    End If

    System.DebugLog(Str(i) + ": " + email.From)
    System.DebugLog("    " + email.Subject)
    System.DebugLog("-")

Next

// Disconnect from the IMAP server.
success = imap.Disconnect()

System.DebugLog("Success.")

// Sample output:

// 	1: iCloud <noreply@email.apple.com>
// 	    Welcome to iCloud Mail.
// 	-
// 	2: "Chilkat Software" <support@chilkatsoft.com>
// 	    This is a test
// 	-
// 	Success.