(Xojo Plugin) Fetch Inbox Email Headers

Downloads the headers of all emails in the Inbox and shows some information about each, such as From, Subject, and whether the email has been seen (already read) or not.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim imap As New Chilkat.Imap

// Connect to an IMAP server.
// Use TLS
imap.Ssl = True
imap.Port = 993
Dim success As Boolean
success = imap.Connect("imap.someMailServer.com")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// Login
success = imap.Login("myLogin","myPassword")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

// Normally, when an email is downloaded, its "Seen" flag is automatically set.
// We don't want our program to be interfering with the "Seen" flags.
// To do this, set the PeekMode to True.
imap.PeekMode = True

// After selecting the mailbox, the NumMessages property
// will contain the number of emails in the mailbox.
// When sequence numbers (not UIDs) are used to reference emails,
// they range from 1 to N, where N is the number of messages in the mailbox.
// This example will download the headers by sequence numbers.
Dim bundle As Chilkat.EmailBundle
bundle = imap.FetchSequenceHeaders(1,imap.NumMessages)
If (imap.LastMethodSuccess <> True) Then
    System.DebugLog(imap.LastErrorText)
    Return
End If

If (bundle.MessageCount = 0) Then
    System.DebugLog("No messages in Inbox.")

    Return
End If

// Loop over the email headers.  
Dim i As Int32
For i = 0 To bundle.MessageCount - 1
    Dim emailHeader As Chilkat.Email
    emailHeader = bundle.GetEmail(i)
    System.DebugLog(emailHeader.From)
    System.DebugLog(emailHeader.Subject)

    // Get the "Seen" flag.
    // When an email is fetched from the IMAP server, the email flags are stored
    // within the email in the "ckx-imap-flags" header.
    // The call to GetMailFlag is simply getting the information from the email header.
    // (it is not communicating with the IMAP server to get this information, because
    // the information was obtained when downloading the headers)
    Dim seenFlag As Int32
    seenFlag = imap.GetMailFlag(emailHeader,"Seen")
    If (seenFlag = 1) Then
        System.DebugLog("This email has been read (already seen)")
    Else
        System.DebugLog("This email has not yet been read (it is not yet seen)")
    End If

    // We can also look directly at the "ckx-imap-flags" header:
    System.DebugLog("ckx-imap-flags: " + emailHeader.GetHeaderField("ckx-imap-flags"))

    System.DebugLog("--")

Next

// Disconnect from the IMAP server.
success = imap.Disconnect()