(Xojo Plugin) IKOF Generation Code for Montenegro Fiscalization Service

Demonstrates computing the IKOF MD5 summary value as described in section 4.3 of this document: https://poreskauprava.gov.me/ResourceManager/FileDownload.aspx?rId=416042&rType=2

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim concatenatedParams As String
concatenatedParams = "12345678|2019-06-12T17:05:43+02:00|9952|bb123bb1231|cc123cc1231|ss123ss123|199.01"

// Get the private key from a pfx file.
Dim pfx As New Chilkat.Pfx
Dim success As Boolean
success = pfx.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success <> True) Then
    System.DebugLog(pfx.LastErrorText)
    Return
End If

Dim privKey As Chilkat.PrivateKey
privKey = pfx.GetPrivateKey(0)
If (pfx.LastMethodSuccess = False) Then
    System.DebugLog(pfx.LastErrorText)
    Return
End If

// Create IIC signature according to RSASSA-PKCS-v1_5 using SHA256
Dim rsa As New Chilkat.Rsa
success = rsa.ImportPrivateKeyObj(privKey)
If (success = False) Then
    System.DebugLog(rsa.LastErrorText)
    Return
End If

// PKCS-v1_5 is used by default.
rsa.EncodingMode = "hex"
rsa.Charset = "utf-8"
Dim hexSig As String
hexSig = rsa.SignStringENC(concatenatedParams,"sha256")

System.DebugLog("Signature value result is: " + hexSig)

// Compute the MD5 hash of the bytes.
Dim crypt As New Chilkat.Crypt2
crypt.EncodingMode = "hex"
crypt.HashAlgorithm = "md5"
Dim bd As New Chilkat.BinData
success = bd.AppendEncoded(hexSig,"hex")
Dim md5_summary As String
md5_summary = crypt.HashBdENC(bd)

System.DebugLog("MD5 summary value is: " + md5_summary)