(Xojo Plugin) Send XMLHttpRequest using PUT, GET, DELETE, or any HTTP Request Method

The PostXml method is the easiest way to send an XMLHttpRequest using the POST HTTP verb (which is by far the most common). To use a different HTTP request method (such as PUT, GET, DELETE, etc.), the SynchronousRequest method should be called. It provides more flexibility in constructing the exact HTTP request desired.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

// The XML sent in the body of the request is application
// specified -- it should contain whatever the server-side
// application is expecting..
Dim xmlStr As String
xmlStr = "<?xml version=""1.0"" encoding=""UTF-8""?><appXml><something>123</something></appXml>"

// If the service endpoint is  "http://www.chilkatsoft.com/xmlEcho.asp",
// then we have the following arguments to be passed to
// SynchronousRequest:
Dim endpointDomain As String
endpointDomain = "www.chilkatsoft.com"
Dim endpointPort As Int32
endpointPort = 80
Dim endpointSsl As Boolean
endpointSsl = False

// Prepare the HTTP request object:
Dim req As New Chilkat.HttpRequest
req.Path = "/xmlEcho.asp"

// This example will use the "PUT" HTTP request method
// (also known as HTTP verb)
req.HttpVerb = "PUT"
req.ContentType = "text/xml"
req.Charset = "utf-8"
Dim success As Boolean
success = req.LoadBodyFromString(xmlStr,"utf-8")

Dim resp As Chilkat.HttpResponse
resp = http.SynchronousRequest(endpointDomain,endpointPort,endpointSsl,req)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

// The raw HTTP request sent by the above call is:

// PUT /xmlEcho.asp HTTP/1.1
// Content-Type: text/xml
// Host: www.chilkatsoft.com
// Content-Length: 81
// 
// <?xml version="1.0" encoding="UTF-8"?><appXml><something>123</something></appXml>

// Examine the Body of the HTTP response
// This would be the XML response sent by the server.
System.DebugLog(resp.BodyStr)