(Xojo Plugin) HTTP - Verify Server is a Trusted Root CA

Demonstrates how to only allow connections to an HTTP server having a certificate with a root that is in our list of trusted CA root certificates.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Starting in v9.5.0.49, all Chilkat classes can be unlocked at once at the beginning of a program
// by calling UnlockBundle.  It requires a Bundle unlock code.
Dim chilkatGlob As New Chilkat.CkGlobal
Dim success As Boolean
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> True) Then
    System.DebugLog(chilkatGlob.LastErrorText)
    Return
End If

//  On my particular system, the root CA cert for this URL is not pre-installed.
//  Note: This may be different for you.
//  Also, this example was written on 29-May-2015.  This URL was valid at the time,
//  but may not be valid at a future date.
Dim url As String
url = "https://animals.nationalgeographic.com/animals/invertebrates/starfish/"

Dim http As New Chilkat.Http

//  Require that the SSL/TLS server certificate is not expired,
//  and that the certificate signature is valid.
//  This does not ensure that it has a chain of authentication to
//  a trusted root.  To ensure that, the TrustedRoots object (below) is required.
http.RequireSslCertVerify = True

//  Do the HTTPS page fetch (through the SSH tunnel)
Dim html As String
html = http.QuickGetStr(url)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

System.DebugLog("The HTTP GET was successful.")

//  Now let's require that HTTP requests to SSL/TLS servers that don't have trusted CA roots
//  should fail.
Dim trustedRoots As New Chilkat.TrustedRoots

//  Indicate that we will trust any pre-installed certificates on this system.
//  (The meaning of pre-installed certificates depends on the operating system, and in
//  some environments there is no such thing as pre-installed certificates.  See the reference
//  documentation for the TrustedRoots class.)
trustedRoots.TrustSystemCaRoots = True

//  Activate the trusted roots globally for all Chilkat objects.
//  This call really shouldn't fail, so we're not checking the return value.
success = trustedRoots.Activate()

//  Given that our previous HTTP GET likely kept the connection open,
//  make sure that all HTTP connections are closed before re-trying.
//  Otherwise, we'll simply be re-using the pre-existing connection.
success = http.CloseAllConnections()

//  Now let's try fetching the URL again.  It should fail this time because
//  there is a requirement that the SSL/TLS server certificate must have a trusted root,
//  and the trusted root for this URL is not installed on my system (but may be different for you..)
html = http.QuickGetStr(url)
If (http.LastMethodSuccess <> True) Then
    System.DebugLog(http.LastErrorText)
    System.DebugLog("Good, the HTTP request failed as expected.")
Else
    System.DebugLog(http.LastErrorText)
    System.DebugLog("Hmmm... we did not fail as expected?")
End If