(Xojo Plugin) Get the Server Certificate, Certificate Chain, and Root CA Certificate

Demonstrates how to get the HTTP server certificate, its certificate chain, and the root CA certificate.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

// We're getting the SSL/TLS certificate, so make sure to connect to the SSL/TLS port (443).
Dim sslCert As Chilkat.Cert
sslCert = http.GetServerSslCert("nationalgeographic.com",443)
If (http.LastMethodSuccess = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

// Note: Prior to v9.5.0.50, this method would fail if the certificate chain could not 
// be completed to the root.  Starting in v9.5.0.50, the incomplete certificate chain 
// will be returned.  The certificate chain's ReachesRoot property can be examined to 
// see if the chain was completed to the root.
Dim certChain As Chilkat.CertChain
certChain = sslCert.GetCertChain()
If (sslCert.LastMethodSuccess = False) Then
    System.DebugLog(sslCert.LastErrorText)

    Return
End If

Dim i As Int32
i = 0
Dim numCerts As Int32
numCerts = certChain.NumCerts
While i < numCerts
    Dim cert As Chilkat.Cert
    cert = certChain.GetCert(i)
    System.DebugLog("SubjectDN " + Str(i) + ": " + cert.SubjectDN)
    System.DebugLog("IssuerDN " + Str(i) + ": " + cert.IssuerDN)

    i = i + 1
Wend

// If the certificate chain reaches the root CA cert, then the last cert in the chain
// is the root CA cert.
If (certChain.ReachesRoot = True) Then
    Dim caCert As Chilkat.Cert
    caCert = certChain.GetCert(numCerts - 1)
    System.DebugLog("CA Root Cert: " + caCert.SubjectDN)

End If