(Xojo Plugin) Google Photos Refresh Access Token

Demonstrates how to refresh a Google Access Token. Refreshing an oauth2 access token does not need to display an interactive browser like when originally getting the OAuth2 access token for the 1st time. Your application can do it automatically without user interaction.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// It is assumed we previously obtained an OAuth2 access token.
// This example loads the JSON access token file 
// saved by this example: Get Google Photos OAuth2 Access Token

Dim jsonToken As New Chilkat.JsonObject
Dim success As Boolean
success = jsonToken.LoadFile("qa_data/tokens/googlePhotos.json")
If (success <> True) Then
    System.DebugLog("Failed to load googlePhotos.json")
    Return
End If

// The access token JSON looks like this:

// {
//   "access_token": "ya29.GlamBqWR6cp8lEfJMmTHVEua45912XLKoq4djyHl_Z3CEIzsPLIZkJSGie5oOrbaggy1rjJHn1zW5bjqSesGr5MEYIp9Hx-0CuvjVYf8srg2jeaDMwMACvzemp43",
//   "expires_in": 3600,
//   "refresh_token": "1/rl6k16nysDl9Bp1EhRH9F1WyRIoiSQAvko49Z4yY694MT5V1QXLj2ibNZGaRgek0",
//   "scope": "https://www.googleapis.com/auth/photoslibrary",
//   "token_type": "Bearer"
// }

Dim oauth2 As New Chilkat.OAuth2

oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

// Replace these with actual values.
oauth2.ClientId = "GOOGLE-CLIENT-ID"
oauth2.ClientSecret = "GOOGLE-CLIENT-SECRET"

// Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

// Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> True) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

// The response contains a new access token, but we must keep
// our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

// Save the new JSON access token response to a file.
Dim sbJson As New Chilkat.StringBuilder
jsonToken.EmitCompact = False
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/googlePhotos.json","utf-8",False)

System.DebugLog("OAuth2 authorization granted!")
System.DebugLog("New Access Token = " + oauth2.AccessToken)