Xojo Plugin Requires Chilkat v10.1.2+

Google OAuth2 Access Token

See more OAuth2 Examples

Demonstrates how to get a Google OAuth2 access token from a desktop application or script. Xojo Plugin

Dim success As Boolean
success = False

//  To further clarify, see OAuth 2.0 Authorization Flow

Dim oauth2 As New Chilkat.OAuth2

//  For Google OAuth2, set the listen port equal to the port used
//  in the Authorized Redirect URL for the Client ID.
//  For example, in this case the Authorized Redirect URL would be http://localhost:55568/
//  Your app should choose a port not likely not used by another application.
oauth2.ListenPort = 55568

oauth2.AuthorizationEndpoint = "https://accounts.google.com/o/oauth2/v2/auth"
oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

//  Replace this with your actual client ID.
oauth2.ClientId = "GOOGLE-CLIENT-ID"

//  This is the scope for Google Drive.
//  See https://developers.google.com/identity/protocols/googlescopes
//  Add the scopes that you need.
oauth2.Scope = "https://www.googleapis.com/auth/drive"

//  Begin the OAuth2 authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> True) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

//  Launch the default browser on the system and navigate to the url.
//  The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = False) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

//  Wait for the interactive user to grant permission in the interactive browser session.
//  We'll wait for a max of 90 seconds.
Dim numMsWaited As Int32
numMsWaited = 0
While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Wend

//  If there was no response from the browser within 90 seconds, then 
//  the AuthFlowState will be equal to 1 or 2.
//  1: Waiting for Redirect. The OAuth2 background thread is waiting to receive the redirect HTTP request from the browser.
//  2: Waiting for Final Response. The OAuth2 background thread is waiting for the final access token response.
//  In that case, cancel the background task started in the call to StartAuth.
If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    System.DebugLog("No response from the browser!")
    Return
End If

//  Check the AuthFlowState to see if authorization was granted, denied, or if some error occurred
//  The possible AuthFlowState values are:
//  3: Completed with Success. The OAuth2 flow has completed, the background thread exited, and the successful JSON response is available in AccessTokenResponse property.
//  4: Completed with Access Denied. The OAuth2 flow has completed, the background thread exited, and the error JSON is available in AccessTokenResponse property.
//  5: Failed Prior to Completion. The OAuth2 flow failed to complete, the background thread exited, and the error information is available in the FailureInfo property.
If (oauth2.AuthFlowState = 5) Then
    System.DebugLog("OAuth2 failed to complete.")
    System.DebugLog(oauth2.FailureInfo)
    Return
End If

If (oauth2.AuthFlowState = 4) Then
    System.DebugLog("OAuth2 authorization was denied.")
    System.DebugLog(oauth2.AccessTokenResponse)
    Return
End If

If (oauth2.AuthFlowState <> 3) Then
    System.DebugLog("Unexpected AuthFlowState:" + Str(oauth2.AuthFlowState))
    Return
End If

//  Save the full JSON access token response to a file.
Dim sbJson As New Chilkat.StringBuilder
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/_googleDrive.json","utf-8",False)

//  The saved JSON response looks like this:

//  	{
//  	 "access_token": "ya39.Ci-XA_C5bGgRDC3UaD-h0_NeL-DVIQnI2gHtBBBHkZzrwlARkwX6R3O0PCDEzRlfaQ",
//  	 "token_type": "Bearer",
//  	 "expires_in": 3600,
//  	 "refresh_token": "1/r_2c_7jddspcdfesrrfKqfXtqo08D6Q-gUU0DsdfVMsx0c"
//  	}
//  
System.DebugLog("OAuth2 authorization granted!")
System.DebugLog("Access Token = " + oauth2.AccessToken)

//  Here is an example showing how to define your OAuth 2.0 Credential in the Google Cloud Console
//  Note: Even though your application is technically not a web app, you should still select "Web Application"
//  because the Redirect URI is going to http://localhost:55568/ where Chilkat will receive it in a background thread.

//